Revision bump. Fixed compilation error 'Error: ‘png_sizeof’ was not declared in this scope' in 0.9.5-r1 to make aseprite work with newer unstable versions of libpng, found this due to a preserve-libs rebuild; this was not found present in 9999 so the sed will not be present of a future version bump.

(Portage version: 2.1.13.7/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

3 files changed, 113 insertions, 3 deletions

diff --git a/dev-games/aseprite/ChangeLog b/dev-games/aseprite/ChangeLog
index c0613b7c5854..9930a6cf0c47 100644
--- a/dev-games/aseprite/ChangeLog
+++ b/dev-games/aseprite/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for dev-games/aseprite
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-games/aseprite/ChangeLog,v 1.4 2013/07/18 20:48:51 creffett Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-games/aseprite/ChangeLog,v 1.5 2013/08/10 15:00:11 tomwij Exp $
+
+*aseprite-0.9.5-r1 (10 Aug 2013)
+
+  10 Aug 2013; Tom Wijsman <TomWij@gentoo.org> +aseprite-0.9.5-r1.ebuild,
+  aseprite-9999.ebuild:
+  Revision bump. Fixed compilation error 'Error: ‘png_sizeof’ was not declared
+  in this scope' in 0.9.5-r1 to make aseprite work with newer unstable versions
+  of libpng, found this due to a preserve-libs rebuild; this was not found
+  present in 9999 so the sed will not be present of a future version bump.
 
   18 Jul 2013; Chris Reffett <creffett@gentoo.org> aseprite-0.9.5.ebuild,
   aseprite-9999.ebuild:
diff --git a/dev-games/aseprite/aseprite-0.9.5-r1.ebuild b/dev-games/aseprite/aseprite-0.9.5-r1.ebuild
new file mode 100644
index 000000000000..c3f453d81cce
--- /dev/null
+++ b/dev-games/aseprite/aseprite-0.9.5-r1.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-games/aseprite/aseprite-0.9.5-r1.ebuild,v 1.1 2013/08/10 15:00:11 tomwij Exp $
+
+EAPI="5"
+
+inherit cmake-utils flag-o-matic
+
+DESCRIPTION="Animated sprite editor & pixel art tool"
+HOMEPAGE="http://www.aseprite.org"
+SRC_URI="http://aseprite.googlecode.com/files/aseprite-${PV}.tar.xz"
+
+LICENSE="GPL-2 FTL"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="debug memleak static test"
+
+RDEPEND="dev-libs/tinyxml
+	media-libs/allegro:0[X,png]
+	media-libs/giflib
+	media-libs/libpng:0
+	net-misc/curl
+	sys-libs/zlib
+	virtual/jpeg
+	x11-libs/libX11"
+DEPEND="${RDEPEND}
+	test? ( dev-cpp/gtest )"
+
+PATCHES=( "${FILESDIR}"/aseprite-0.9.5-as-needed.patch )
+
+DOCS=( docs/quickref.odt
+	docs/files/ase.txt
+	docs/files/fli.txt
+	docs/files/msk.txt
+	docs/files/pic.txt
+	docs/files/picpro.txt )
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# Fix to make flag-o-matic work.
+	if use debug ; then
+		sed -i '/-DNDEBUG/d' CMakeLists.txt || die
+	fi
+
+	# Only do a static link with Allegro if the user explicitly wants it.
+	if ! use static ; then
+		sed -i '/-DALLEGRO_STATICLINK/d' CMakeLists.txt || die
+	fi
+
+	# Remove long compiling tests for users with FEATURES="-test",
+	# also removes the gtest dependency from the build.
+	if ! use test ; then
+		sed -i '/^find_unittests/d' src/CMakeLists.txt || die
+		sed -i '/include_directories(.*third_party\/gtest.*)/d' src/CMakeLists.txt || die
+		sed -i '/add_subdirectory(gtest)/d' third_party/CMakeLists.txt || die
+	fi
+
+	# Fix from https://465450.bugs.gentoo.org/attachment.cgi?id=345154
+	# for "error: ‘png_sizeof’ was not declared in this scope".
+	sed -i 's/png_\(sizeof\)/\1/g' src/file/png_format.cpp || die
+}
+
+src_configure() {
+	use debug && append-cppflags -DDEBUGMODE -D_DEBUG
+
+	local mycmakeargs
+
+	mycmakeargs=(
+		-DENABLE_UPDATER=OFF
+		-DUSE_SHARED_ALLEGRO4=ON
+		-DUSE_SHARED_CURL=ON
+		-DUSE_SHARED_GIFLIB=ON
+		-DUSE_SHARED_JPEGLIB=ON
+		-DUSE_SHARED_LIBLOADPNG=ON
+		-DUSE_SHARED_LIBPNG=ON
+		-DUSE_SHARED_TINYXML=ON
+		-DUSE_SHARED_ZLIB=ON
+		-DFULLSCREEN_PLATFORM=ON
+		$(cmake-utils_use_enable memleak)
+		$(cmake-utils_use_use static STATIC_LIBC)
+	)
+
+	if use test ; then
+		mycmakeargs+=(
+			-DUSE_SHARED_GTEST=ON
+		)
+	fi
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	elog "Warning: aseprite might not choose the resolution correctly; so, you might need"
+	elog "         to change the resolution once using the -resolution WxH[xBPP] argument."
+	elog ""
+	elog "         On subsequent runs, aseprite will remember the resolution you have set."
+	elog ""
+	elog "         For example: \`aseprite -resolution 1440x900\`"
+}
diff --git a/dev-games/aseprite/aseprite-9999.ebuild b/dev-games/aseprite/aseprite-9999.ebuild
index a740c3ae10a2..14754066708d 100644
--- a/dev-games/aseprite/aseprite-9999.ebuild
+++ b/dev-games/aseprite/aseprite-9999.ebuild
@@ -1,8 +1,8 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-games/aseprite/aseprite-9999.ebuild,v 1.2 2013/07/18 20:48:51 creffett Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-games/aseprite/aseprite-9999.ebuild,v 1.3 2013/08/10 15:00:11 tomwij Exp $
 
-EAPI=5
+EAPI="5"
 
 inherit cmake-utils flag-o-matic git-2