version bump

(Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

1 files changed, 68 insertions, 0 deletions

diff --git a/dev-games/irrlicht/irrlicht-1.8.ebuild b/dev-games/irrlicht/irrlicht-1.8.ebuild
new file mode 100644
index 000000000000..8419bd84adb5
--- /dev/null
+++ b/dev-games/irrlicht/irrlicht-1.8.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-games/irrlicht/irrlicht-1.8.ebuild,v 1.1 2012/12/07 23:43:23 hasufell Exp $
+
+EAPI=5
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="open source high performance realtime 3D engine written in C++"
+HOMEPAGE="http://irrlicht.sourceforge.net/"
+SRC_URI="mirror://sourceforge/irrlicht/${P}.zip"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug doc"
+
+RDEPEND="virtual/jpeg
+	media-libs/libpng:0
+	app-arch/bzip2
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXxf86vm"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	x11-proto/xproto
+	x11-proto/xf86vidmodeproto"
+
+S=${WORKDIR}/${P}/source/Irrlicht
+
+src_prepare() {
+	cd "${WORKDIR}"/${P} || die
+	edos2unix include/IrrCompileConfig.h
+
+	epatch \
+		"${FILESDIR}"/${P}-gentoo.patch \
+		"${FILESDIR}"/${P}-config.patch \
+		"${FILESDIR}"/${P}-demoMake.patch
+
+	sed -i \
+		-e 's:\.\./\.\./media:../media:g' \
+		$(grep -rl '\.\./\.\./media' examples) \
+		|| die 'sed failed'
+}
+
+src_compile() {
+	tc-export CXX CC AR
+	emake NDEBUG=$(usex debug "" "1") sharedlib staticlib
+}
+
+src_install() {
+	cd "${WORKDIR}"/${P} || die
+
+	dolib.a lib/Linux/libIrrlicht.a
+	dolib.so lib/Linux/libIrrlicht.so*
+
+	# create library symlinks
+	dosym lib/Linux/libIrrlicht.so.1.8.0 /usr/$(get_libdir)/libIrrlicht.so.1.8
+	dosym lib/Linux/libIrrlicht.so.1.8.0 /usr/$(get_libdir)/libIrrlicht.so
+
+	insinto /usr/include/${PN}
+	doins include/*
+
+	dodoc changes.txt readme.txt
+	if use doc ; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples media
+	fi
+}