A bioinformatics library for haskell (requested by Martin MOKREJŠ).

(Portage version: 2.2.1_p20/cvs/Linux x86_64, signed Manifest commit with key 611FF3AA)

1 files changed, 61 insertions, 0 deletions

diff --git a/dev-haskell/bio/bio-0.5.3.ebuild b/dev-haskell/bio/bio-0.5.3.ebuild
new file mode 100644
index 000000000000..a39ab545de90
--- /dev/null
+++ b/dev-haskell/bio/bio-0.5.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-haskell/bio/bio-0.5.3.ebuild,v 1.1 2013/09/12 20:19:20 slyfox Exp $
+
+EAPI=5
+
+# ebuild generated by hackport 0.3.2.9999
+
+CABAL_FEATURES="bin lib profile haddock hoogle hscolour"
+inherit haskell-cabal
+
+DESCRIPTION="A bioinformatics library"
+HOMEPAGE="http://biohaskell.org/Libraries/Bio"
+SRC_URI="mirror://hackage/packages/archive/${PN}/${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86"
+IUSE="+examples test"
+
+RDEPEND=">=dev-haskell/binary-0.4:=[profile?] <dev-haskell/binary-0.8:=[profile?]
+		dev-haskell/mtl:=[profile?]
+		dev-haskell/parallel:=[profile?]
+		dev-haskell/parsec:=[profile?]
+		>=dev-haskell/quickcheck-2:=[profile?]
+		dev-haskell/random:=[profile?]
+		>=dev-haskell/tagsoup-0.8:=[profile?]
+		>=dev-lang/ghc-6.10.4:="
+DEPEND="${RDEPEND}
+		>=dev-haskell/cabal-1.6"
+
+src_prepare() {
+	cabal_chdeps \
+		'binary >=0.4 && <0.5' 'binary >=0.4 && <0.8'
+}
+
+src_configure() {
+	haskell-cabal_src_configure \
+		$(cabal_flag examples examples) \
+		$(cabal_flag test test)
+}
+
+src_test() {
+	dist/build/qc/qc || die
+}
+
+src_install() {
+	haskell-cabal_src_install
+
+	use test && rm "${ED}"/usr/bin/qc
+	# many examples collide with dev-haskell/flower
+	if use examples ; then
+		pushd "${ED}"/usr/bin
+		local example
+		for example in *
+		do
+			mv "${example}" "${PN}-example-${example}"
+		done
+		popd
+	fi
+}