Revbump to fix the tests. Fixes bug #220245. Thanks to Jose Quinteiro <gentoo@quinteiro.com> for the patch.

(Portage version: 2.1.4.4)

1 files changed, 56 insertions, 0 deletions

diff --git a/dev-java/jid3/jid3-0.46-r1.ebuild b/dev-java/jid3/jid3-0.46-r1.ebuild
new file mode 100644
index 000000000000..8226f40269d5
--- /dev/null
+++ b/dev-java/jid3/jid3-0.46-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/jid3/jid3-0.46-r1.ebuild,v 1.1 2008/05/28 18:43:52 serkan Exp $
+
+JAVA_PKG_IUSE="doc source test"
+# To make sure the javadoc patch doesn't break things
+WANT_SPLIT_WANT="true"
+
+inherit eutils java-pkg-2 java-ant-2
+
+MY_P=${P/-/_}
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="ID3 Class Library Implementation"
+HOMEPAGE="http://jid3.blinkenlights.org/"
+SRC_URI="http://jid3.blinkenlights.org/release/${MY_P}.tar.gz"
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+# Feel free to submit a patch that doesn't bundle the classes
+# into the result jar
+RDEPEND=">=virtual/jre-1.4
+	test? ( =dev-java/junit-3.8* )"
+
+DEPEND=">=virtual/jdk-1.4
+	test? ( =dev-java/junit-3.8* )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}/${PV}-javadoc.patch"
+	epatch "${FILESDIR}/${PV}-tests-and-unicode.patch"
+	rm -v "${S}"/dist/*.jar || die
+	if use !test; then
+		rm -rv "${S}/src/org/blinkenlights/jid3/test" || die
+	fi
+
+}
+
+src_compile() {
+	local junit="-Dlibs.junit.classpath"
+	eant jar $(use_doc) \
+		$(use test && echo ${junit}=$(java-pkg_getjars junit))
+}
+
+src_test() {
+	ejunit -cp dist/JID3.jar org.blinkenlights.jid3.test.AllTests
+}
+
+src_install() {
+	java-pkg_dojar dist/JID3.jar
+	use doc && java-pkg_dojavadoc dist/javadoc
+	use source && java-pkg_dosrc src/
+}