bump; add chicken, clisp, mzscheme and R use flags, deps and use_with's; drop keywords because of new deps

(Portage version: 2.1.3.19)

3 files changed, 83 insertions, 1 deletions

diff --git a/dev-lang/swig/ChangeLog b/dev-lang/swig/ChangeLog
index f6773637354d..c9022ede53ea 100644
--- a/dev-lang/swig/ChangeLog
+++ b/dev-lang/swig/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lang/swig
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/swig/ChangeLog,v 1.96 2007/07/31 12:58:47 hkbst Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/swig/ChangeLog,v 1.97 2007/11/16 15:10:25 hkbst Exp $
+
+*swig-1.3.32 (16 Nov 2007)
+
+  16 Nov 2007; Marijn Schouten <hkBst@gentoo.org> +swig-1.3.32.ebuild:
+  bump; add chicken, clisp, mzscheme and R use flags, deps and use_with's;
+  drop keywords because of new deps
 
   31 Jul 2007; Marijn Schouten <hkBst@gentoo.org> metadata.xml:
   take over maintainership
diff --git a/dev-lang/swig/files/digest-swig-1.3.32 b/dev-lang/swig/files/digest-swig-1.3.32
new file mode 100644
index 000000000000..36b8abc2d931
--- /dev/null
+++ b/dev-lang/swig/files/digest-swig-1.3.32
@@ -0,0 +1,3 @@
+MD5 5db15e9265ade86b349fcb61c82299ea swig-1.3.32.tar.gz 4409358
+RMD160 de9aed91799b11d99b658f5caeb52706109693d6 swig-1.3.32.tar.gz 4409358
+SHA256 22a175de0e30e284a6aa80991b768820e11abf4629f4eeb21e86e7a2d3708d9e swig-1.3.32.tar.gz 4409358
diff --git a/dev-lang/swig/swig-1.3.32.ebuild b/dev-lang/swig/swig-1.3.32.ebuild
new file mode 100644
index 000000000000..9107fb4ad51a
--- /dev/null
+++ b/dev-lang/swig/swig-1.3.32.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/swig/swig-1.3.32.ebuild,v 1.1 2007/11/16 15:10:25 hkbst Exp $
+
+inherit flag-o-matic mono eutils #48511
+
+DESCRIPTION="Simplified Wrapper and Interface Generator"
+HOMEPAGE="http://www.swig.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="chicken clisp doc guile java lua mono mzscheme ocaml perl php pike python R ruby tcl tk" #gcj
+RESTRICT="test"
+
+DEPEND="
+chicken? ( dev-scheme/chicken )
+clisp? ( dev-lisp/clisp )
+guile? ( dev-scheme/guile )
+java? ( virtual/jdk )
+lua? ( dev-lang/lua )
+mono? ( dev-lang/mono )
+mzscheme? ( dev-scheme/drscheme )
+perl? ( dev-lang/perl )
+php? ( virtual/php )
+pike? ( dev-lang/pike )
+python? ( virtual/python )
+R? ( dev-lang/R )
+ocaml? ( dev-lang/ocaml )
+ruby? ( virtual/ruby )
+tcl? ( dev-lang/tcl )
+tk? ( dev-lang/tk )
+"
+# gcj? ( sys-devel/gcc[+gcj] )
+
+
+src_compile() {
+	strip-flags
+
+	local myconf
+	if use ruby ; then
+		local rubyver=$(ruby --version | cut -d '.' -f 1,2)
+		export RUBY="/usr/$(get_libdir)/ruby/${rubyver/ruby /}/"
+	fi
+
+	econf \
+		$(use_with chicken) \
+		$(use_with clisp) \
+		$(use_with guile) \
+		$(use_with java java "${JAVA_HOME}") \
+		$(use_with java javaincl "${JAVA_HOME}/include") \
+		$(use_with lua) \
+		$(use_with mono csharp) \
+		$(use_with mzscheme) \
+		$(use_with ocaml) \
+		$(use_with perl perl5 /usr/bin/perl) \
+		$(use_with php php4) \
+		$(use_with pike) \
+		$(use_with python python python) \
+		$(use_with R r) \
+		$(use_with ruby ruby /usr/bin/ruby) \
+		$(use_with tk x) \
+		$(use_with tcl) \
+		|| die
+	emake || die
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	dodoc ANNOUNCE CHANGES CHANGES.current FUTURE NEW README TODO
+	use doc && dohtml -r Doc/{Devel,Manual}
+}