Version bump. Add support for parallel compilation, improved compiler performance. Bug fixes and binding updates.

(Portage version: 2.2_rc89/cvs/Linux x86_64)

2 files changed, 54 insertions, 1 deletions

diff --git a/dev-lang/vala/ChangeLog b/dev-lang/vala/ChangeLog
index b1e41e1e852e..d77f2713c7d0 100644
--- a/dev-lang/vala/ChangeLog
+++ b/dev-lang/vala/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lang/vala
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/vala/ChangeLog,v 1.27 2010/09/19 17:28:34 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/vala/ChangeLog,v 1.28 2010/10/06 22:02:03 eva Exp $
+
+*vala-0.11.0 (06 Oct 2010)
+
+  06 Oct 2010; Gilles Dartiguelongue <eva@gentoo.org> +vala-0.11.0.ebuild:
+  Version bump. Add support for parallel compilation, improved compiler
+  performance. Bug fixes and binding updates.
 
 *vala-0.10.0 (19 Sep 2010)
 
diff --git a/dev-lang/vala/vala-0.11.0.ebuild b/dev-lang/vala/vala-0.11.0.ebuild
new file mode 100644
index 000000000000..da73d7161d49
--- /dev/null
+++ b/dev-lang/vala/vala-0.11.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/vala/vala-0.11.0.ebuild,v 1.1 2010/10/06 22:02:03 eva Exp $
+
+EAPI="3"
+GCONF_DEBUG="no"
+
+inherit gnome2
+
+DESCRIPTION="Vala - Compiler for the GObject type system"
+HOMEPAGE="http://live.gnome.org/Vala"
+
+LICENSE="LGPL-2.1"
+SLOT="0.12"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test +vapigen coverage"
+
+RDEPEND=">=dev-libs/glib-2.26"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	|| ( sys-devel/bison dev-util/byacc dev-util/yacc )
+	dev-util/pkgconfig
+	dev-libs/libxslt
+	test? ( dev-libs/dbus-glib )"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-unversioned
+		$(use_enable vapigen)
+		$(use_enable coverage)"
+	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README"
+
+	if use coverage && has ccache ${FEATURES}; then
+		ewarn "USE=coverage does not work well with ccache; valac and libvala"
+		ewarn "built with ccache and USE=coverage create temporary files inside"
+		ewarn "CCACHE_DIR and mess with ccache's working, as well as causing"
+		ewarn "sandbox violations when used to compile other packages."
+		ewarn "It is STRONGLY recommended that you disable one of them."
+	fi
+}
+
+src_install() {
+	gnome2_src_install
+	mv "${ED}"/usr/share/aclocal/vala.m4 \
+		"${ED}"/usr/share/aclocal/vala-${SLOT/./-}.m4 || die "failed to move vala m4 macro"
+	find "${ED}" -name "*.la" -delete || die "la file removal failed"
+}