New ebuild split off gamin. Initial ebuild inspired by Pacho Ramos, closes bug #217861.

(Portage version: 2.2_rc15/cvs/Linux 2.6.24-gentoo-r8-mactel x86_64)

1 files changed, 76 insertions, 0 deletions

diff --git a/dev-libs/libgamin/libgamin-0.1.10.ebuild b/dev-libs/libgamin/libgamin-0.1.10.ebuild
new file mode 100644
index 000000000000..5704ef2f2c65
--- /dev/null
+++ b/dev-libs/libgamin/libgamin-0.1.10.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgamin/libgamin-0.1.10.ebuild,v 1.1 2008/11/24 23:07:56 eva Exp $
+
+inherit autotools eutils flag-o-matic libtool python
+
+MY_PN=${PN//lib/}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Library providing the FAM File Alteration Monitor API"
+HOMEPAGE="http://www.gnome.org/~veillard/gamin/"
+SRC_URI="http://www.gnome.org/~veillard/${MY_PN}/sources/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="debug kernel_linux python"
+
+RESTRICT="test" # need gam-server
+
+RDEPEND="python? ( virtual/python )
+	!<app-admin/gamin-0.1.10"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	# Fix compile warnings; bug #188923
+	epatch "${FILESDIR}/${MY_PN}-0.1.9-freebsd.patch"
+
+	# Fix collision problem due to intermediate library, upstream bug #530635
+	epatch "${FILESDIR}/${P}-noinst-lib.patch"
+
+	# autoconf is required as the user-cflags patch modifies configure.in
+	# however, elibtoolize is also required, so when the above patch is
+	# removed, replace the following call with a call to elibtoolize
+	eautoreconf
+}
+
+src_compile() {
+	# fixes bug #225403
+	#append-flags "-D_GNU_SOURCE"
+
+	econf --disable-debug \
+		--disable-server \
+		$(use_enable kernel_linux inotify) \
+		$(use_enable debug debug-api) \
+		$(use_with python)
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "installation failed"
+
+	dodoc AUTHORS ChangeLog README TODO NEWS doc/*txt
+	dohtml doc/*
+}
+
+pkg_postinst() {
+	if use python; then
+		python_version
+		python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages
+	fi
+}
+
+pkg_postrm() {
+	if use python; then
+		python_mod_cleanup /usr/$(get_libdir)/python*/site-packages
+	fi
+}