Version bump.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

2 files changed, 77 insertions, 1 deletions

diff --git a/dev-libs/libusb/ChangeLog b/dev-libs/libusb/ChangeLog
index cd8cc888f2b9..afc315960e54 100644
--- a/dev-libs/libusb/ChangeLog
+++ b/dev-libs/libusb/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/libusb
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libusb/ChangeLog,v 1.166 2014/06/18 19:15:28 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libusb/ChangeLog,v 1.167 2014/06/19 10:51:43 ssuominen Exp $
+
+*libusb-1.0.19 (19 Jun 2014)
+
+  19 Jun 2014; Samuli Suominen <ssuominen@gentoo.org> +libusb-1.0.19.ebuild:
+  Version bump.
 
   18 Jun 2014; Michał Górny <mgorny@gentoo.org> libusb-1.0.18.ebuild:
   Update dependencies to require guaranteed EAPI=5 or multilib ebuilds, bug
diff --git a/dev-libs/libusb/libusb-1.0.19.ebuild b/dev-libs/libusb/libusb-1.0.19.ebuild
new file mode 100644
index 000000000000..a62fd428dfd9
--- /dev/null
+++ b/dev-libs/libusb/libusb-1.0.19.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libusb/libusb-1.0.19.ebuild,v 1.1 2014/06/19 10:51:43 ssuominen Exp $
+
+EAPI=5
+inherit eutils toolchain-funcs multilib-minimal
+
+DESCRIPTION="Userspace access to USB devices"
+HOMEPAGE="http://libusb.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 -x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="debug doc examples static-libs test udev"
+
+RDEPEND="udev? ( >=virtual/udev-208-r2[${MULTILIB_USEDEP}] )
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20130224-r7
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	!udev? ( virtual/os-headers )"
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable udev) \
+		$(use_enable debug debug-log) \
+		$(use_enable test tests-build)
+}
+
+multilib_src_compile() {
+	emake
+
+	if multilib_is_native_abi; then
+		use doc && emake -C doc docs
+	fi
+}
+
+multilib_src_test() {
+	emake check
+
+	# noinst_PROGRAMS from tests/Makefile.am
+	tests/stress || die
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	if multilib_is_native_abi; then
+		gen_usr_ldscript -a usb-1.0
+
+		use doc && dohtml doc/html/*
+	fi
+}
+
+multilib_src_install_all() {
+	prune_libtool_files
+
+	dodoc AUTHORS ChangeLog NEWS PORTING README TODO
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.{c,h}
+		insinto /usr/share/doc/${PF}/examples/getopt
+		doins examples/getopt/*.{c,h}
+	fi
+}