Version bump.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-libs/msgpack/msgpack-1.0.0.ebuild b/dev-libs/msgpack/msgpack-1.0.0.ebuild
new file mode 100644
index 000000000000..525ee999add9
--- /dev/null
+++ b/dev-libs/msgpack/msgpack-1.0.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/msgpack/msgpack-1.0.0.ebuild,v 1.1 2015/03/21 06:14:48 radhermit Exp $
+
+EAPI=5
+inherit cmake-multilib
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}-c.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}-c/releases/download/cpp-${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="MessagePack is a binary-based efficient data interchange format"
+HOMEPAGE="http://msgpack.org/ https://github.com/msgpack/msgpack-c/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="+cxx static-libs test"
+
+DEPEND="
+	test? (
+		>=dev-cpp/gtest-1.6.0-r2[${MULTILIB_USEDEP}]
+		sys-libs/zlib[${MULTILIB_USEDEP}]
+	)
+"
+
+DOCS=( README.md )
+PATCHES=(
+	"${FILESDIR}"/${P}-cflags.patch
+	"${FILESDIR}"/${P}-static.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use cxx MSGPACK_ENABLE_CXX)
+		$(cmake-utils_use static-libs MSGPACK_STATIC)
+		$(cmake-utils_use test MSGPACK_BUILD_TESTS)
+	)
+	cmake-multilib_src_configure
+}