Version bump, bug#512874

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key BF20DC51)

2 files changed, 67 insertions, 1 deletions

diff --git a/dev-libs/nettle/ChangeLog b/dev-libs/nettle/ChangeLog
index ecf29cf2a3ee..87d82578bb00 100644
--- a/dev-libs/nettle/ChangeLog
+++ b/dev-libs/nettle/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/nettle
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/nettle/ChangeLog,v 1.119 2015/03/27 06:41:28 alonbl Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/nettle/ChangeLog,v 1.120 2015/04/09 20:47:58 alonbl Exp $
+
+*nettle-3.1 (09 Apr 2015)
+
+  09 Apr 2015; Alon Bar-Lev <alonbl@gentoo.org> +nettle-3.1.ebuild:
+  Version bump, bug#512874
 
 *nettle-2.7.1-r4 (27 Mar 2015)
 
diff --git a/dev-libs/nettle/nettle-3.1.ebuild b/dev-libs/nettle/nettle-3.1.ebuild
new file mode 100644
index 000000000000..bc52571023fd
--- /dev/null
+++ b/dev-libs/nettle/nettle-3.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/nettle/nettle-3.1.ebuild,v 1.1 2015/04/09 20:47:58 alonbl Exp $
+
+EAPI=5
+AUTOTOOLS_AUTORECONF=yes
+
+inherit eutils autotools-multilib multilib toolchain-funcs
+
+DESCRIPTION="Low-level cryptographic library"
+HOMEPAGE="http://www.lysator.liu.se/~nisse/nettle/"
+SRC_URI="http://www.lysator.liu.se/~nisse/archive/${P}.tar.gz"
+
+LICENSE="|| ( LGPL-3 LGPL-2.1 )"
+SLOT="0/6" # subslot = libnettle soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x86-solaris"
+IUSE="doc +gmp neon static-libs test cpu_flags_x86_aes"
+
+DEPEND="gmp? ( dev-libs/gmp:0[${MULTILIB_USEDEP}] )"
+RDEPEND="${DEPEND}
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20131008-r17
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/nettle/nettle-stdint.h
+)
+
+src_prepare() {
+	sed -e '/CFLAGS=/s: -ggdb3::' \
+		-e 's/solaris\*)/sunldsolaris*)/' \
+		-i configure.ac || die
+
+	# conditionally build tests and examples required by tests
+	use test || sed -i '/SUBDIRS/s/testsuite examples//' Makefile.in || die
+
+	autotools-utils_src_prepare
+}
+
+multilib_src_configure() {
+	# --disable-openssl bug #427526
+	ECONF_SOURCE="${S}" econf \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--disable-openssl \
+		--disable-fat \
+		$(use_enable gmp public-key) \
+		$(use_enable static-libs static) \
+		$(tc-is-static-only && echo --disable-shared) \
+		$(use_enable doc documentation) \
+		$(use_enable neon arm-neon) \
+		$(use_enable cpu_flags_x86_aes x86-aesni)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	if use doc ; then
+		dohtml nettle.html
+		dodoc nettle.pdf
+	fi
+}