Version bump. Add doc USE flag.

(Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

2 files changed, 66 insertions, 1 deletions

diff --git a/dev-libs/rasqal/ChangeLog b/dev-libs/rasqal/ChangeLog
index 38c26d5ae012..b31eb8b7747f 100644
--- a/dev-libs/rasqal/ChangeLog
+++ b/dev-libs/rasqal/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/rasqal
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/rasqal/ChangeLog,v 1.60 2011/08/13 17:24:25 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/rasqal/ChangeLog,v 1.61 2011/08/26 09:16:20 radhermit Exp $
+
+*rasqal-0.9.27 (26 Aug 2011)
+
+  26 Aug 2011; Tim Harder <radhermit@gentoo.org> +rasqal-0.9.27.ebuild:
+  Version bump. Add doc USE flag.
 
   13 Aug 2011; Markus Meier <maekke@gentoo.org> rasqal-0.9.19.ebuild:
   arm stable, bug #376893
diff --git a/dev-libs/rasqal/rasqal-0.9.27.ebuild b/dev-libs/rasqal/rasqal-0.9.27.ebuild
new file mode 100644
index 000000000000..310c6a38d1cc
--- /dev/null
+++ b/dev-libs/rasqal/rasqal-0.9.27.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/rasqal/rasqal-0.9.27.ebuild,v 1.1 2011/08/26 09:16:20 radhermit Exp $
+
+EAPI=4
+
+DESCRIPTION="library that handles Resource Description Framework (RDF)"
+HOMEPAGE="http://librdf.org/rasqal/"
+SRC_URI="http://download.librdf.org/source/${P}.tar.gz"
+
+LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos"
+IUSE="+crypt doc gmp +mhash pcre static-libs test xml"
+
+RDEPEND="media-libs/raptor:2
+	pcre? ( dev-libs/libpcre )
+	xml? ( dev-libs/libxml2 )
+	!gmp? ( dev-libs/mpfr )
+	gmp? ( dev-libs/gmp )
+	crypt? (
+		!mhash? ( dev-libs/libgcrypt )
+		mhash? ( app-crypt/mhash )
+	)"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	sys-devel/flex
+	test? ( dev-perl/XML-DOM )"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_configure() {
+	local regex=posix
+	local decimal=mpfr
+	local digest=internal
+
+	use pcre && regex=pcre
+	use gmp && decimal=gmp
+
+	if use crypt; then
+		digest=gcrypt
+		use mhash && digest=mhash
+	fi
+
+	econf \
+		$(use_enable pcre) \
+		$(use_enable static-libs static) \
+		$(use_enable xml xml2) \
+		--with-regex-library=${regex} \
+		--with-digest-library=${digest} \
+		--with-decimal=${decimal} \
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+}
+
+src_install() {
+	default
+	dohtml {NEWS,README,RELEASE}.html
+	use doc || rm -rf "${ED}"/usr/share/doc/${PF}/html/rasqal
+	find "${ED}" -name '*.la' -exec rm -f '{}' +
+}