Add 0.18.3 which depends on =dev-libs/isl-0.14:0/14. We skip 0.18.2 doesn't build against any versions of isl and is skipped in their update log.

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

3 files changed, 66 insertions, 5 deletions

diff --git a/dev-libs/cloog/ChangeLog b/dev-libs/cloog/ChangeLog
index 8e489f82f91e..c5a527add03b 100644
--- a/dev-libs/cloog/ChangeLog
+++ b/dev-libs/cloog/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/cloog
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/cloog/ChangeLog,v 1.27 2014/12/26 11:28:20 ago Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/cloog/ChangeLog,v 1.28 2015/02/05 11:52:17 blueness Exp $
+
+*cloog-0.18.3 (05 Feb 2015)
+
+  05 Feb 2015; Anthony G. Basile <blueness@gentoo.org> +cloog-0.18.3.ebuild,
+  cloog-9999.ebuild:
+  Add 0.18.3 which depends on =dev-libs/isl-0.14:0/14.  We skip 0.18.2 doesn't
+  build against any versions of isl and is skipped in their update log.
 
   26 Dec 2014; Agostino Sarubbo <ago@gentoo.org> cloog-0.18.1.ebuild:
   Stable for sparc, wrt bug #516152
diff --git a/dev-libs/cloog/cloog-0.18.3.ebuild b/dev-libs/cloog/cloog-0.18.3.ebuild
new file mode 100644
index 000000000000..beac6de09f9b
--- /dev/null
+++ b/dev-libs/cloog/cloog-0.18.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/cloog/cloog-0.18.3.ebuild,v 1.1 2015/02/05 11:52:17 blueness Exp $
+
+EAPI="5"
+
+inherit eutils multilib-minimal
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://repo.or.cz/cloog.git"
+	inherit autotools git-2
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+	SRC_URI="http://www.bastoul.net/cloog/pages/download/${P}.tar.gz"
+fi
+
+DESCRIPTION="A loop generator for scanning polyhedra"
+HOMEPAGE="http://www.bastoul.net/cloog/"
+
+LICENSE="LGPL-2.1"
+SLOT="0/4"
+IUSE="static-libs"
+
+RDEPEND=">=dev-libs/gmp-5.1.3-r1[${MULTILIB_USEDEP}]
+	>=dev-libs/isl-0.14:0/14[${MULTILIB_USEDEP}]
+	!<dev-libs/cloog-ppl-0.15.10"
+DEPEND="${DEPEND}
+	virtual/pkgconfig"
+
+DOCS=( README )
+
+src_prepare() {
+	if [[ ${PV} == "9999" ]] ; then
+		./get_submodules.sh
+		eautoreconf -i
+	else
+		# m4/ax_create_pkgconfig_info.m4 includes LDFLAGS
+		# sed to avoid eautoreconf
+		sed -i -e '/Libs:/s:@LDFLAGS@ ::' configure || die
+	fi
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		--with-gmp=system \
+		--with-isl=system \
+		--with-osl=no \
+		$(use_enable static-libs static)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}
diff --git a/dev-libs/cloog/cloog-9999.ebuild b/dev-libs/cloog/cloog-9999.ebuild
index 35deb48ba8b3..e9ec5bdf62c6 100644
--- a/dev-libs/cloog/cloog-9999.ebuild
+++ b/dev-libs/cloog/cloog-9999.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/cloog/cloog-9999.ebuild,v 1.3 2014/11/04 03:36:19 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/cloog/cloog-9999.ebuild,v 1.4 2015/02/05 11:52:17 blueness Exp $
 
 EAPI="5"
 
@@ -22,7 +22,7 @@ SLOT="0/4"
 IUSE="static-libs"
 
 RDEPEND=">=dev-libs/gmp-5.1.3-r1[${MULTILIB_USEDEP}]
-	>=dev-libs/isl-0.12.2:0/10[${MULTILIB_USEDEP}]
+	>=dev-libs/isl-0.14:0/14[${MULTILIB_USEDEP}]
 	!<dev-libs/cloog-ppl-0.15.10"
 DEPEND="${DEPEND}
 	virtual/pkgconfig"