Version bump.

(Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 59 insertions, 1 deletions

diff --git a/dev-python/apsw/ChangeLog b/dev-python/apsw/ChangeLog
index e05bb84713e5..6029384e28a0 100644
--- a/dev-python/apsw/ChangeLog
+++ b/dev-python/apsw/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/apsw
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/apsw/ChangeLog,v 1.57 2013/05/02 07:27:50 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/apsw/ChangeLog,v 1.58 2013/05/30 01:07:04 radhermit Exp $
+
+*apsw-3.7.17_p1 (30 May 2013)
+
+  30 May 2013; Tim Harder <radhermit@gentoo.org> +apsw-3.7.17_p1.ebuild:
+  Version bump.
 
 *apsw-3.7.16.2_p1 (02 May 2013)
 
diff --git a/dev-python/apsw/apsw-3.7.17_p1.ebuild b/dev-python/apsw/apsw-3.7.17_p1.ebuild
new file mode 100644
index 000000000000..260a56711eb9
--- /dev/null
+++ b/dev-python/apsw/apsw-3.7.17_p1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/apsw/apsw-3.7.17_p1.ebuild,v 1.1 2013/05/30 01:07:04 radhermit Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2,3_3} )
+
+inherit distutils-r1
+
+MY_P=${PN}-${PV/_p/-r}
+
+DESCRIPTION="APSW - Another Python SQLite Wrapper"
+HOMEPAGE="http://code.google.com/p/apsw/"
+SRC_URI="http://apsw.googlecode.com/files/${MY_P}.zip"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="doc"
+
+RDEPEND=">=dev-db/sqlite-${PV%_p*}[extensions]"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=( "${FILESDIR}"/${PN}-3.6.20.1-fix_tests.patch )
+
+python_compile() {
+	if [[ ${EPYTHON} == python2* ]]; then
+		local CFLAGS="${CFLAGS} -fno-strict-aliasing"
+		export CFLAGS
+	fi
+	distutils-r1_python_compile --enable=load_extension
+}
+
+src_test() {
+	# tests use overlapping database files
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+	distutils-r1_src_test
+}
+
+python_test() {
+	"${PYTHON}" setup.py build_test_extension || die "Building of test loadable extension failed"
+	"${PYTHON}" tests.py -v || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use doc ; then
+		dohtml -r doc/*
+	fi
+}