Bump

(Portage version: 2.2.7/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 65 insertions, 1 deletions

diff --git a/dev-python/cython/ChangeLog b/dev-python/cython/ChangeLog
index f1dbf605443a..5e430de47b6b 100644
--- a/dev-python/cython/ChangeLog
+++ b/dev-python/cython/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/cython
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/cython/ChangeLog,v 1.103 2013/11/14 05:54:56 prometheanfire Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cython/ChangeLog,v 1.104 2013/11/22 07:50:32 patrick Exp $
+
+*cython-0.19.2 (22 Nov 2013)
+
+  22 Nov 2013; Patrick Lauer <patrick@gentoo.org> +cython-0.19.2.ebuild:
+  Bump
 
 *cython-0.19.1-r1 (14 Nov 2013)
 
diff --git a/dev-python/cython/cython-0.19.2.ebuild b/dev-python/cython/cython-0.19.2.ebuild
new file mode 100644
index 000000000000..3b4aa69b460f
--- /dev/null
+++ b/dev-python/cython/cython-0.19.2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cython/cython-0.19.2.ebuild,v 1.1 2013/11/22 07:50:32 patrick Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )
+
+inherit distutils-r1 flag-o-matic
+
+MY_PN="Cython"
+MY_P="${MY_PN}-${PV/_/}"
+
+DESCRIPTION="A Python to C compiler"
+HOMEPAGE="http://www.cython.org/ http://pypi.python.org/pypi/Cython"
+SRC_URI="http://www.cython.org/release/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris ~x64-solaris"
+IUSE="doc test"
+
+# Note: update numpy dep when it is fixed for py3.3.
+RDEPEND=""
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx )
+	test? (
+		>=dev-python/numpy-1.6.1-r1[$(python_gen_usedep 'python2*' 'python3_[12]' )]
+	)"
+
+S="${WORKDIR}/${MY_PN}-${PV%_*}"
+
+python_compile() {
+	if [[ ${EPYTHON} == python2* ]]; then
+		local CFLAGS CXXFLAGS
+		append-flags -fno-strict-aliasing
+	fi
+
+	# Python gets confused when it is in sys.path before build.
+	local PYTHONPATH
+	export PYTHONPATH
+
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	"${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests \
+		|| die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( CHANGES.rst README.txt ToDo.txt USAGE.txt )
+	use doc && local HTML_DOCS=( docs/build/html/. )
+
+	distutils-r1_python_install_all
+}