bump; upstream have dropped py3.2 support and added py3.3 support

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 67 insertions, 1 deletions

diff --git a/dev-python/hacking/ChangeLog b/dev-python/hacking/ChangeLog
index 46bb5d33cddf..7f28170f90cf 100644
--- a/dev-python/hacking/ChangeLog
+++ b/dev-python/hacking/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/hacking
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/hacking/ChangeLog,v 1.9 2014/03/30 12:45:45 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/hacking/ChangeLog,v 1.10 2014/04/19 02:30:43 idella4 Exp $
+
+*hacking-0.8.1 (19 Apr 2014)
+
+  19 Apr 2014; Ian Delaney <idella4@gentoo.org> +hacking-0.8.1.ebuild:
+  bump; upstream have dropped py3.2 support and added py3.3 support
 
 *hacking-0.5.6 (30 Mar 2014)
 
diff --git a/dev-python/hacking/hacking-0.8.1.ebuild b/dev-python/hacking/hacking-0.8.1.ebuild
new file mode 100644
index 000000000000..9edd931197c8
--- /dev/null
+++ b/dev-python/hacking/hacking-0.8.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/hacking/hacking-0.8.1.ebuild,v 1.1 2014/04/19 02:30:43 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3} )
+
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Nova API"
+HOMEPAGE="https://github.com/openstack-dev/hacking"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+		>=dev-python/pbr-0.5.21[${PYTHON_USEDEP}]
+		<dev-python/pbr-1.0[${PYTHON_USEDEP}]
+		test? ( >=dev-python/coverage-3.6[${PYTHON_USEDEP}]
+			>=dev-python/fixtures-0.3.14[${PYTHON_USEDEP}]
+			dev-python/subunit[${PYTHON_USEDEP}]
+			>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+			>=dev-python/testrepository-0.0.17-r2[${PYTHON_USEDEP}]
+			>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+			>=dev-python/testtools-0.9.32[${PYTHON_USEDEP}]
+			${RDEPEND} )"
+RDEPEND="~dev-python/pep8-1.4.5[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-0.7.2[${PYTHON_USEDEP}]
+		<dev-python/pyflakes-0.7.4[${PYTHON_USEDEP}]
+		~dev-python/flake8-2.0[${PYTHON_USEDEP}]
+		>=dev-python/six-1.4.1[${PYTHON_USEDEP}]"
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	sed -e 's:intersphinx_mapping:#&:' -i doc/source/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && sphinx-build -b html -c doc/source/ doc/source/ doc/source/html
+}
+
+python_test() {
+	# https://bugs.launchpad.net/hacking/+bug/1265520
+	# Although fixed in trunk, the fix is a version change in pep8
+	# which cannot be simply dropped in here.
+	if python_is_python3; then
+		sed -e 's:test_pep8:_&:' -i hacking/tests/test_doctest.py || die
+	fi
+	testr init || die "testr init died"
+	testr run || die "testsuite failed under ${EPYTHON}"
+	flake8 "${PN}"/tests || die "flake8 drew error on a run over ${PN}/tests folder"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/source/html/. )
+	distutils-r1_python_install_all
+}