Convert to distutils-r1, bug 493042.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

2 files changed, 53 insertions, 3 deletions

diff --git a/dev-python/pyode/ChangeLog b/dev-python/pyode/ChangeLog
index c83efc35fa6b..c65f44e32838 100644
--- a/dev-python/pyode/ChangeLog
+++ b/dev-python/pyode/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/pyode
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyode/ChangeLog,v 1.18 2011/04/14 20:33:21 ranger Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyode/ChangeLog,v 1.19 2013/12/01 17:25:48 floppym Exp $
+
+*pyode-1.2.0_p20100322-r1 (01 Dec 2013)
+
+  01 Dec 2013; Mike Gilbert <floppym@gentoo.org>
+  +pyode-1.2.0_p20100322-r1.ebuild:
+  Convert to distutils-r1, bug 493042.
 
   14 Apr 2011; Brent Baude <ranger@gentoo.org> pyode-1.2.0_p20100322.ebuild:
   stable ppc, bug 362471
@@ -76,4 +82,3 @@
 
   30 Dec 2004; Bryan Østergaard <kloeri@gentoo.org> +pyode-1.0.0.ebuild:
   Initial import. Ebuild submitted by Daniel Holth <dholth@fastmail.fm>.
-
diff --git a/dev-python/pyode/pyode-1.2.0_p20100322-r1.ebuild b/dev-python/pyode/pyode-1.2.0_p20100322-r1.ebuild
new file mode 100644
index 000000000000..758c7e0462da
--- /dev/null
+++ b/dev-python/pyode/pyode-1.2.0_p20100322-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyode/pyode-1.2.0_p20100322-r1.ebuild,v 1.1 2013/12/01 17:25:48 floppym Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_6,2_7} pypy2_0 )
+
+inherit distutils-r1
+
+MY_P="${P/pyode/PyODE}"
+SNAPSHOT_DATE="2010-03-22"	# This is a snapshot
+
+DESCRIPTION="Python bindings to the ODE physics engine"
+HOMEPAGE="http://pyode.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/PyODE-snapshot-${SNAPSHOT_DATE}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
+IUSE="examples"
+
+RDEPEND=">=dev-games/ode-0.7
+	>=dev-python/pyrex-0.9.4.1[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/PyODE-snapshot-${SNAPSHOT_DATE}"
+
+python_compile() {
+	python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# The build system doesnt error if it fails to build
+	# the ode library so we need our own sanity check
+	[[ -n $(find "${D}" -name ode.so) ]] || die "ode.so is missing"
+
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}