bump; drop py2.6 pypy2_0 add py3.4 support, add IUSE doc, dep, doc build

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 59 insertions, 1 deletions

diff --git a/dev-python/pyxattr/ChangeLog b/dev-python/pyxattr/ChangeLog
index 1d050211f40f..94629fc27f32 100644
--- a/dev-python/pyxattr/ChangeLog
+++ b/dev-python/pyxattr/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pyxattr
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyxattr/ChangeLog,v 1.61 2014/03/31 21:03:55 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyxattr/ChangeLog,v 1.62 2014/06/03 03:02:37 idella4 Exp $
+
+*pyxattr-0.5.3 (03 Jun 2014)
+
+  03 Jun 2014; Ian Delaney <idella4@gentoo.org> +pyxattr-0.5.3.ebuild:
+  bump; drop py2.6 pypy2_0 add py3.4 support, add IUSE doc, dep, doc build
 
   31 Mar 2014; Michał Górny <mgorny@gentoo.org> pyxattr-0.5.2.ebuild,
   pyxattr-9999.ebuild:
diff --git a/dev-python/pyxattr/pyxattr-0.5.3.ebuild b/dev-python/pyxattr/pyxattr-0.5.3.ebuild
new file mode 100644
index 000000000000..39385e031b03
--- /dev/null
+++ b/dev-python/pyxattr/pyxattr-0.5.3.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyxattr/pyxattr-0.5.3.ebuild,v 1.1 2014/06/03 03:02:37 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} pypy )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Python interface to xattr"
+HOMEPAGE="http://pyxattr.k1024.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+	http://pyxattr.k1024.org/downloads/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="sys-apps/attr"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	sed -i -e 's:, "-Werror"::' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake doc
+}
+
+src_test() {
+	# Perform the tests in /var/tmp; that location is more likely
+	# to have xattr support than /tmp which is often tmpfs.
+	export TESTDIR=/var/tmp
+
+	einfo 'Please note that the tests fail if xattrs are not supported'
+	einfo 'by the filesystem used for /var/tmp.'
+	distutils-r1_src_test
+}
+
+python_test() {
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/html/. )
+	distutils-r1_python_install_all
+}