Version bump.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 52 insertions, 1 deletions

diff --git a/dev-python/greenlet/ChangeLog b/dev-python/greenlet/ChangeLog
index 972722e2d12b..29c5ff0fa718 100644
--- a/dev-python/greenlet/ChangeLog
+++ b/dev-python/greenlet/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/greenlet
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/greenlet/ChangeLog,v 1.28 2014/05/23 13:04:03 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/greenlet/ChangeLog,v 1.29 2014/08/08 17:07:42 radhermit Exp $
+
+*greenlet-0.4.3 (08 Aug 2014)
+
+  08 Aug 2014; Tim Harder <radhermit@gentoo.org> +greenlet-0.4.3.ebuild:
+  Version bump.
 
   23 May 2014; Ian Delaney <idella4@gentoo.org> greenlet-0.4.2.ebuild:
   drop py2.6 add py3.4
diff --git a/dev-python/greenlet/greenlet-0.4.3.ebuild b/dev-python/greenlet/greenlet-0.4.3.ebuild
new file mode 100644
index 000000000000..e421d796eb6a
--- /dev/null
+++ b/dev-python/greenlet/greenlet-0.4.3.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/greenlet/greenlet-0.4.3.ebuild,v 1.1 2014/08/08 17:07:42 radhermit Exp $
+
+EAPI=5
+
+# Note: greenlet is built-in in pypy
+PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Lightweight in-process concurrent programming"
+HOMEPAGE="http://pypi.python.org/pypi/greenlet/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.zip"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc"
+
+DEPEND="app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_compile() {
+	if [[ ${EPYTHON} == python2.7 ]]; then
+		local CFLAGS=${CFLAGS} CXXFLAGS=${CXXFLAGS}
+		append-flags -fno-strict-aliasing
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	"${PYTHON}" run-tests.py -n || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	distutils-r1_python_install_all
+}