Bump

(Portage version: 2.2.1/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 68 insertions, 1 deletions

diff --git a/dev-python/networkx/ChangeLog b/dev-python/networkx/ChangeLog
index 531fea2b08d7..fbd8b0c8a563 100644
--- a/dev-python/networkx/ChangeLog
+++ b/dev-python/networkx/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/networkx
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/networkx/ChangeLog,v 1.20 2013/08/18 10:42:18 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/networkx/ChangeLog,v 1.21 2013/09/02 06:43:14 patrick Exp $
+
+*networkx-1.8.1 (02 Sep 2013)
+
+  02 Sep 2013; Patrick Lauer <patrick@gentoo.org> +networkx-1.8.1.ebuild:
+  Bump
 
 *networkx-1.6-r1 (18 Aug 2013)
 
diff --git a/dev-python/networkx/networkx-1.8.1.ebuild b/dev-python/networkx/networkx-1.8.1.ebuild
new file mode 100644
index 000000000000..b6e066151b0e
--- /dev/null
+++ b/dev-python/networkx/networkx-1.8.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/networkx/networkx-1.8.1.ebuild,v 1.1 2013/09/02 06:43:14 patrick Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python tools to manipulate graphs and complex networks"
+HOMEPAGE="http://networkx.lanl.gov http://pypi.python.org/pypi/networkx"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~ppc-macos ~x86-linux ~x86-macos"
+IUSE="doc examples test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/pygraphviz[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+	)"
+RDEPEND="
+	examples? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/pygraphviz[${PYTHON_USEDEP}]
+		virtual/pyparsing[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+	)"
+
+python_compile_all() {
+	if use doc; then
+		sed \
+			-e "s:^\t\./:\t${PYTHON} :g" \
+			-i doc/Makefile || die
+		emake -C doc html
+	fi
+}
+
+python_test() {
+	nosetests || die
+}
+
+python_install_all() {
+	# Oh my.
+	rm -r "${ED}"usr/share/doc/${P} || die
+
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+
+	distutils-r1_python_install_all
+}