Multiple fixes. Please read the ChangeLog to see what changed

(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

3 files changed, 85 insertions, 9 deletions

diff --git a/dev-python/pythonmagick/ChangeLog b/dev-python/pythonmagick/ChangeLog
index d9ee662d4ef6..d36bea2fe8be 100644
--- a/dev-python/pythonmagick/ChangeLog
+++ b/dev-python/pythonmagick/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/pythonmagick
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pythonmagick/ChangeLog,v 1.31 2011/11/03 10:24:19 djc Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pythonmagick/ChangeLog,v 1.32 2012/01/23 22:25:36 hwoarang Exp $
+
+*pythonmagick-0.9.7-r1 (23 Jan 2012)
+
+  23 Jan 2012; Markos Chandras <hwoarang@gentoo.org>
+  +pythonmagick-0.9.7-r1.ebuild, pythonmagick-0.9.7.ebuild:
+  Multiple fixes. Please read the ChangeLog to see what changed
 
 *pythonmagick-0.9.7 (03 Nov 2011)
 
diff --git a/dev-python/pythonmagick/pythonmagick-0.9.7-r1.ebuild b/dev-python/pythonmagick/pythonmagick-0.9.7-r1.ebuild
new file mode 100644
index 000000000000..f2c883a28476
--- /dev/null
+++ b/dev-python/pythonmagick/pythonmagick-0.9.7-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pythonmagick/pythonmagick-0.9.7-r1.ebuild,v 1.1 2012/01/23 22:25:36 hwoarang Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2:2.6"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="2.4 2.5 *-jython *-pypy-*"
+PYTHON_EXPORT_PHASE_FUNCTIONS="1"
+
+inherit autotools eutils python
+
+MY_PN="PythonMagick"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python bindings for ImageMagick"
+HOMEPAGE="http://www.imagemagick.org/script/api.php"
+SRC_URI="http://www.imagemagick.org/download/python/${MY_P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND=">=dev-libs/boost-1.48[python]
+	>=media-gfx/imagemagick-6.4"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+PYTHON_CXXFLAGS=("2.* + -fno-strict-aliasing")
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-0.9.1-use_active_python_version.patch"
+	epatch "${FILESDIR}/${PN}-0.9.2-fix_detection_of_python_includedir.patch"
+
+	sed -e "s/AM_PATH_PYTHON(3.1)/AM_PATH_PYTHON(2.6)/" -i configure.ac || die "sed failed"
+
+	eautoreconf
+
+	python_clean_py-compile_files
+
+	# Support Python 3.
+	sed -e "s/import _PythonMagick/from . import _PythonMagick/" -i PythonMagick/__init__.py || die "sed failed"
+
+	python_src_prepare
+}
+
+src_configure() {
+	configuration() {
+		sed -e "s/-lboost_python/-lboost_python-${PYTHON_ABI}/" -i Makefile.in
+		econf \
+			--disable-static \
+			--with-boost-python="boost_python-${PYTHON_ABI}"
+	}
+	python_execute_function -s configuration
+}
+
+src_install() {
+	python_src_install
+	python_clean_installation_image
+}
+
+pkg_postinst() {
+	python_mod_optimize PythonMagick
+}
+
+pkg_postrm() {
+	python_mod_cleanup PythonMagick
+}
diff --git a/dev-python/pythonmagick/pythonmagick-0.9.7.ebuild b/dev-python/pythonmagick/pythonmagick-0.9.7.ebuild
index 31b25b70ab61..e0b5c98eb6ed 100644
--- a/dev-python/pythonmagick/pythonmagick-0.9.7.ebuild
+++ b/dev-python/pythonmagick/pythonmagick-0.9.7.ebuild
@@ -1,11 +1,11 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pythonmagick/pythonmagick-0.9.7.ebuild,v 1.1 2011/11/03 10:24:18 djc Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pythonmagick/pythonmagick-0.9.7.ebuild,v 1.2 2012/01/23 22:25:36 hwoarang Exp $
 
 EAPI="3"
 PYTHON_DEPEND="2:2.6"
 SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="2.[45] 3.* *-jython"
+RESTRICT_PYTHON_ABIS="2.4 2.5 3.* *-jython *-pypy-*"
 PYTHON_EXPORT_PHASE_FUNCTIONS="1"
 
 inherit autotools eutils python
@@ -22,8 +22,8 @@ SLOT="0"
 KEYWORDS="~amd64 ~ppc ~x86"
 IUSE=""
 
-RDEPEND=">=media-gfx/imagemagick-6.4
-	>=dev-libs/boost-1.35.0[python]"
+RDEPEND="<dev-libs/boost-1.48[python]
+	>=media-gfx/imagemagick-6.4"
 DEPEND="${RDEPEND}
 	dev-util/pkgconfig"
 
@@ -39,8 +39,7 @@ src_prepare() {
 
 	eautoreconf
 
-	# Disable byte-compilation.
-	echo "#!/bin/sh" > config/py-compile
+	python_clean_py-compile_files
 
 	python_src_prepare
 }