Initial import of session as needed by rr (for the gemcutter testsuite). Warning: license unknown.

(Portage version: 2.2_rc61/cvs/Linux x86_64)

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-ruby/session/session-2.4.0.ebuild b/dev-ruby/session/session-2.4.0.ebuild
new file mode 100644
index 000000000000..9ec52d392dcf
--- /dev/null
+++ b/dev-ruby/session/session-2.4.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/session/session-2.4.0.ebuild,v 1.1 2010/01/05 17:46:27 flameeyes Exp $
+
+EAPI=2
+
+# jruby → “fork is unsafe and disabled by default on JRuby“
+USE_RUBY="ruby18 ruby19"
+
+RUBY_FAKEGEM_TASK_TEST=""
+RUBY_FAKEGEM_TASK_DOC=""
+
+RUBY_FAKEGEM_EXTRADOC="HISTORY README TODO"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A set of classes to drive external programs via pipe"
+HOMEPAGE="http://codeforpeople.com/lib/ruby/session/"
+SRC_URI="http://codeforpeople.com/lib/ruby/session/${P}.tgz"
+
+# actually no license information provided; upstream has been
+# contacted on the matter.
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+ruby_add_bdepend test virtual/ruby-test-unit
+
+all_ruby_prepare() {
+	# needed to void a collision with the Timeout::Error alias in Ruby
+	# 1.8.7 at least.
+	sed -i -e 's:TimeoutError:SessionTimeoutError:' test/session.rb || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib test/*.rb || die "tests failed"
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	docinto examples
+	dodoc sample/* || die
+}