Version bump.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key C6085806)

3 files changed, 97 insertions, 5 deletions

diff --git a/dev-util/glade/ChangeLog b/dev-util/glade/ChangeLog
index e9747d89c447..df944442c124 100644
--- a/dev-util/glade/ChangeLog
+++ b/dev-util/glade/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/glade
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/ChangeLog,v 1.195 2013/12/24 15:53:01 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/ChangeLog,v 1.196 2014/02/09 20:28:44 eva Exp $
+
+*glade-3.16.1 (09 Feb 2014)
+
+  09 Feb 2014; Gilles Dartiguelongue <eva@gentoo.org> glade-3.16.0.ebuild,
+  +glade-3.16.1.ebuild:
+  Version bump.
 
 *glade-3.16.0 (24 Dec 2013)
 
diff --git a/dev-util/glade/glade-3.16.0.ebuild b/dev-util/glade/glade-3.16.0.ebuild
index dc297e0e1988..bd79d8c64147 100644
--- a/dev-util/glade/glade-3.16.0.ebuild
+++ b/dev-util/glade/glade-3.16.0.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/glade-3.16.0.ebuild,v 1.1 2013/12/24 15:53:01 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/glade-3.16.0.ebuild,v 1.2 2014/02/09 20:28:44 eva Exp $
 
 EAPI="5"
 GCONF_DEBUG="yes"
@@ -13,7 +13,7 @@ DESCRIPTION="A user interface designer for GTK+ and GNOME"
 HOMEPAGE="http://glade.gnome.org/"
 
 LICENSE="GPL-2+ FDL-1.1+"
-SLOT="3.10/4" # subslot = suffix of libgladeui-2.so
+SLOT="3.10/6" # subslot = suffix of libgladeui-2.so
 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
 IUSE="+introspection python"
 
diff --git a/dev-util/glade/glade-3.16.1.ebuild b/dev-util/glade/glade-3.16.1.ebuild
new file mode 100644
index 000000000000..89883ff6c190
--- /dev/null
+++ b/dev-util/glade/glade-3.16.1.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/glade-3.16.1.ebuild,v 1.1 2014/02/09 20:28:44 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit eutils gnome2 python-single-r1 versionator virtualx
+
+DESCRIPTION="A user interface designer for GTK+ and GNOME"
+HOMEPAGE="http://glade.gnome.org/"
+
+LICENSE="GPL-2+ FDL-1.1+"
+SLOT="3.10/6" # subslot = suffix of libgladeui-2.so
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="+introspection python"
+
+RDEPEND="
+	dev-libs/atk[introspection?]
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/libxml2-2.4.0:2
+	x11-libs/cairo:=
+	x11-libs/gdk-pixbuf:2[introspection?]
+	>=x11-libs/gtk+-3.10:3[introspection?]
+	x11-libs/pango[introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-1.32 )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/pygobject-3.8:3[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	dev-libs/libxslt
+	>=dev-util/gtk-doc-am-1.13
+	>=dev-util/intltool-0.41.0
+	virtual/pkgconfig
+"
+# eautoreconf requires:
+#	dev-libs/gobject-introspection-common
+#	gnome-base/gnome-common
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# To avoid file collison with other slots, rename help module.
+	# Prevent the UI from loading glade:3's gladeui devhelp documentation.
+	epatch "${FILESDIR}/${PN}-3.14.1-doc-version.patch"
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--enable-gladeui \
+		--enable-libtool-lock \
+		$(use_enable introspection) \
+		$(use_enable python) \
+		ITSTOOL=$(type -P true)
+}
+
+src_test() {
+	Xemake check
+}
+
+src_install() {
+	# modify Name in .desktop file to avoid confusion with other slots
+	sed -e 's:^\(Name.*=Glade\):\1 '$(get_version_component_range 1-2): \
+		-i data/glade.desktop || die "sed of data/glade.desktop failed"
+	# modify name in .devhelp2 file to avoid shadowing with glade:3 docs
+	sed -e 's:name="gladeui":name="gladeui-2":' \
+		-i doc/html/gladeui.devhelp2 || die "sed of gladeui.devhelp2 failed"
+	gnome2_src_install
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	if ! has_version dev-util/devhelp ; then
+		elog "You may want to install dev-util/devhelp for integration API"
+		elog "documentation support."
+	fi
+}