Version bump

(Portage version: 2.2_rc33/cvs/Linux x86_64)

2 files changed, 109 insertions, 1 deletions

diff --git a/dev-util/qt-creator/ChangeLog b/dev-util/qt-creator/ChangeLog
index fb3698af2a45..ec6ba5a99f96 100644
--- a/dev-util/qt-creator/ChangeLog
+++ b/dev-util/qt-creator/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/qt-creator
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/qt-creator/ChangeLog,v 1.21 2009/06/30 23:03:01 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/qt-creator/ChangeLog,v 1.22 2009/07/14 10:50:30 hwoarang Exp $
+
+*qt-creator-1.2.1 (14 Jul 2009)
+
+  14 Jul 2009; Markos Chandras <hwoarang@gentoo.org>
+  +qt-creator-1.2.1.ebuild:
+  Version bump
 
   30 Jun 2009; Markos Chandras <hwoarang@gentoo.org>
   -qt-creator-1.2.0.ebuild, -qt-creator-1.2.0-r1.ebuild:
diff --git a/dev-util/qt-creator/qt-creator-1.2.1.ebuild b/dev-util/qt-creator/qt-creator-1.2.1.ebuild
new file mode 100644
index 000000000000..fd1f85e03a4f
--- /dev/null
+++ b/dev-util/qt-creator/qt-creator-1.2.1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/qt-creator/qt-creator-1.2.1.ebuild,v 1.1 2009/07/14 10:50:30 hwoarang Exp $
+
+EAPI="2"
+
+inherit qt4 multilib
+
+MY_PN="${PN/-/}"
+MY_P="${P}-src"
+
+DESCRIPTION="Lightweight IDE for C++ development centering around Qt"
+HOMEPAGE="http://labs.qtsoftware.com/page/Projects/Tools/QtCreator"
+SRC_URI="http://download.qtsoftware.com/${MY_PN}/${MY_P}.zip"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="bineditor bookmarks +cmake debug +debugger +designer doc examples fakevim git kde perforce qtscript subversion"
+
+DEPEND=">=x11-libs/qt-assistant-4.5.0_rc1
+	>=x11-libs/qt-gui-4.5.0_rc1[dbus,qt3support]"
+
+RDEPEND="${DEPEND}
+	>=x11-libs/qt-sql-4.5.0_rc1
+	>=x11-libs/qt-svg-4.5.0_rc1
+	>=x11-libs/qt-test-4.5.0_rc1
+	>=x11-libs/qt-webkit-4.5.0_rc1
+	!kde? ( || ( >=x11-libs/qt-phonon-4.5.0_rc1 media-sound/phonon ) )
+	kde? ( media-sound/phonon )
+	cmake? ( dev-util/cmake )
+	debugger? ( sys-devel/gdb )
+	examples? ( >=x11-libs/qt-demo-4.5.0_rc1 )
+	git? ( dev-util/git )
+	qtscript? ( >=x11-libs/qt-script-4.5.0_rc1 )
+	subversion? ( dev-util/subversion )"
+
+PLUGINS="bookmarks bineditor cmake debugger designer fakevim git perforce qtscript subversion"
+
+PATCHES=(
+	"${FILESDIR}/docs_gen.patch"
+)
+
+S="${WORKDIR}/${MY_P}"
+
+LANGS="de es it ja ru"
+
+for x in ${LANGS}; do
+	IUSE="${IUSE} linguas_${x}"
+done
+
+src_prepare() {
+	qt4_src_prepare
+
+	# bug 263087
+	for plugin in ${PLUGINS};do
+		if ! use ${plugin};then
+			einfo "Disabling ${plugin} support"
+			if [[ ${plugin} == "cmake" ]];then
+				plugin="cmakeprojectmanager"
+			elif [[ ${plugin} == "qtscript" ]];then
+				plugin="qtscripteditor"
+			fi
+			sed -i "/plugin_${plugin}/s:^:#:" src/plugins/plugins.pro \
+				|| die "Failed to disabled ${plugin} plugin"
+		fi
+	done
+
+	if use perforce;then
+		ewarn
+		ewarn "You have enabled perforce plugin."
+		ewarn "In order to use it, you need to manually"
+		ewarn "download perforce client from http://www.perforce.com/perforce/downloads/index.html"
+		ewarn
+		ebeep 5
+	fi
+}
+
+src_configure() {
+	eqmake4 ${MY_PN}.pro IDE_LIBRARY_BASENAME="$(get_libdir)"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}/usr" install_subtargets || die "emake install failed"
+	# because qtcreator.bin executable make nosense
+	mv "${D}"/usr/bin/${MY_PN}.bin "${D}"/usr/bin/${MY_PN} || die "failed to rename executable"
+	if use doc;then
+		emake INSTALL_ROOT="${D}/usr" install_qch_docs || die "emake install qch_docs failed"
+	fi
+	make_desktop_entry ${MY_PN} QtCreator qtcreator_logo_48 \
+		'Qt;Development;IDE' || die "make_desktop_entry failed"
+
+	# install translations
+	insinto /usr/share/${MY_PN}/translations/
+	for x in ${LINGUAS};do
+		for lang in ${LANGS};do
+			if [[ ${x} == ${lang} ]];then
+				doins share/${MY_PN}/translations/${MY_PN}_${x}.qm
+			fi
+		done
+	done
+}