revbump; convert -> distutils-r1, rm old, fixes Bug #541150, endorsement provided in said bug

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

3 files changed, 81 insertions, 89 deletions

diff --git a/dev-vcs/qct/ChangeLog b/dev-vcs/qct/ChangeLog
index c1a6ce208ec7..1d242d053bd7 100644
--- a/dev-vcs/qct/ChangeLog
+++ b/dev-vcs/qct/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-vcs/qct
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/qct/ChangeLog,v 1.9 2011/01/18 12:55:44 arfrever Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/qct/ChangeLog,v 1.10 2015/02/25 01:04:48 idella4 Exp $
+
+*qct-1.7-r1 (25 Feb 2015)
+
+  25 Feb 2015; Ian Delaney <idella4@gentoo.org> +qct-1.7-r1.ebuild,
+  -qct-1.7.ebuild:
+  revbump; convert -> distutils-r1, rm old, fixes Bug #541150, endorsement
+  provided in said bug
 
   18 Jan 2011; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
   qct-1.7.ebuild:
@@ -37,4 +44,3 @@
   15 Jun 2009; Ben de Groot <yngwin@gentoo.org> +files/qct.rc:
   Initial import from qting-edge overlay. Ebuild developed by Dror Levin and
   contributors in bug 162963.
-
diff --git a/dev-vcs/qct/qct-1.7-r1.ebuild b/dev-vcs/qct/qct-1.7-r1.ebuild
new file mode 100644
index 000000000000..742a42ccab1e
--- /dev/null
+++ b/dev-vcs/qct/qct-1.7-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/qct/qct-1.7-r1.ebuild,v 1.1 2015/02/25 01:04:48 idella4 Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1
+
+DESCRIPTION="PyQt based commit tool for many VCSs"
+HOMEPAGE="http://qct.sourceforge.net/"
+SRC_URI="http://qct.sourceforge.net/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bazaar cvs mercurial monotone subversion"
+
+DEPEND="app-text/asciidoc[${PYTHON_USEDEP}]
+	app-text/xmlto
+	dev-python/PyQt4[${PYTHON_USEDEP}]
+	bazaar? ( dev-vcs/bzr[${PYTHON_USEDEP}] )
+	cvs? ( dev-vcs/cvs )
+	mercurial? ( dev-vcs/mercurial[${PYTHON_USEDEP}] )
+	monotone? ( dev-vcs/monotone )
+	subversion? ( dev-vcs/subversion[${PYTHON_USEDEP}] )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	rm qctlib/vcs/p4.py
+
+	# support for git requires cogito which isn't in portage
+	rm qctlib/vcs/git.py
+	rm qctlib/vcs/cg.py
+
+	use bazaar || rm qctlib/vcs/bzr.py
+	use cvs || rm qctlib/vcs/cvs.py
+	use mercurial || rm qctlib/vcs/hg.py
+	use monotone || rm qctlib/vcs/mtn.py
+	use subversion || rm qctlib/vcs/svn.py
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# manpage and html docs are built using asciidoc
+	make -C doc man html || die
+	doman doc/qct.1 || die
+	dohtml doc/qct.1.html || die
+
+	if use bazaar; then
+		insinto "$(python_get_sitedir)/bzrlib/plugins"
+		doins plugins/qctBzrPlugin.py
+	fi
+
+	if use mercurial; then
+		insinto "$(python_get_sitedir)/hgext"
+		doins hgext/qct.py
+		insinto /etc/mercurial/hgrc.d
+		doins "${FILESDIR}/qct.rc"
+	fi
+}
diff --git a/dev-vcs/qct/qct-1.7.ebuild b/dev-vcs/qct/qct-1.7.ebuild
deleted file mode 100644
index 43aba7642054..000000000000
--- a/dev-vcs/qct/qct-1.7.ebuild
+++ /dev/null
@@ -1,86 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/qct/qct-1.7.ebuild,v 1.9 2011/01/18 12:55:44 arfrever Exp $
-
-EAPI="3"
-PYTHON_DEPEND="2"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="3.* *-jython"
-
-inherit distutils
-
-DESCRIPTION="PyQt based commit tool for many VCSs"
-HOMEPAGE="http://qct.sourceforge.net/"
-SRC_URI="http://qct.sourceforge.net/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="bazaar cvs mercurial monotone subversion"
-
-DEPEND="app-text/asciidoc
-	app-text/xmlto
-	dev-python/PyQt4
-	bazaar? ( dev-vcs/bzr )
-	cvs? ( dev-vcs/cvs )
-	mercurial? ( dev-vcs/mercurial )
-	monotone? ( dev-vcs/monotone )
-	subversion? ( dev-vcs/subversion )"
-RDEPEND="${DEPEND}"
-
-S="${WORKDIR}/${PN}"
-
-pkg_setup() {
-	python_pkg_setup
-
-	PYTHON_MODNAME="qctlib"
-	if use bazaar; then
-		PYTHON_MODNAME+=" bzrlib/plugins/qctBzrPlugin.py"
-	fi
-	if use mercurial; then
-		PYTHON_MODNAME+=" hgext/qct.py"
-	fi
-}
-
-src_prepare() {
-	distutils_src_prepare
-
-	rm qctlib/vcs/p4.py
-
-	# support for git requires cogito which isn't in portage
-	rm qctlib/vcs/git.py
-	rm qctlib/vcs/cg.py
-
-	use bazaar || rm qctlib/vcs/bzr.py
-	use cvs || rm qctlib/vcs/cvs.py
-	use mercurial || rm qctlib/vcs/hg.py
-	use monotone || rm qctlib/vcs/mtn.py
-	use subversion || rm qctlib/vcs/svn.py
-}
-
-src_install() {
-	distutils_src_install
-
-	# manpage and html docs are built using asciidoc
-	make -C doc man html || die
-	doman doc/qct.1 || die
-	dohtml doc/qct.1.html || die
-
-	if use bazaar; then
-		install_bazaar_plugins() {
-			insinto "$(python_get_sitedir)/bzrlib/plugins" || return 1
-			doins plugins/qctBzrPlugin.py || return 1
-		}
-		python_execute_function -q install_bazaar_plugins
-	fi
-
-	if use mercurial; then
-		install_mercurial_extension() {
-			insinto "$(python_get_sitedir)/hgext" || return 1
-			doins hgext/qct.py || return 1
-		}
-		python_execute_function -q install_mercurial_extension
-		insinto /etc/mercurial/hgrc.d || die
-		doins "${FILESDIR}/qct.rc" || die
-	fi
-}