Revision bump: port to distutils-r1 eclass

(Portage version: 2.2.0_alpha171/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

2 files changed, 58 insertions, 1 deletions

diff --git a/dev-vcs/hgview/ChangeLog b/dev-vcs/hgview/ChangeLog
index 89d2a3438d3b..3ba216d0b0d2 100644
--- a/dev-vcs/hgview/ChangeLog
+++ b/dev-vcs/hgview/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-vcs/hgview
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/hgview/ChangeLog,v 1.10 2013/04/16 18:04:24 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/hgview/ChangeLog,v 1.11 2013/04/16 18:33:50 pinkbyte Exp $
+
+*hgview-1.7.1-r1 (16 Apr 2013)
+
+  16 Apr 2013; Sergey Popov <pinkbyte@gentoo.org> +hgview-1.7.1-r1.ebuild:
+  Revision bump: port to distutils-r1 eclass
 
 *hgview-1.7.1 (16 Apr 2013)
 
diff --git a/dev-vcs/hgview/hgview-1.7.1-r1.ebuild b/dev-vcs/hgview/hgview-1.7.1-r1.ebuild
new file mode 100644
index 000000000000..071d398e1768
--- /dev/null
+++ b/dev-vcs/hgview/hgview-1.7.1-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/hgview/hgview-1.7.1-r1.ebuild,v 1.1 2013/04/16 18:33:50 pinkbyte Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_IN_SOURCE_BUILD=1
+inherit distutils-r1
+
+DESCRIPTION="PyQt4-based Mercurial log navigator"
+HOMEPAGE="http://www.logilab.org/project/hgview"
+SRC_URI="http://ftp.logilab.org/pub/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/PyQt4[${PYTHON_USEDEP},X]
+	dev-python/qscintilla-python[${PYTHON_USEDEP}]
+	dev-vcs/mercurial[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? (
+		app-text/asciidoc
+		app-text/xmlto
+	)"
+
+python_configure_all() {
+	mydistutilsargs=(
+		build $(use doc || echo --no-doc)
+	)
+}
+
+src_prepare() {
+	# https://www.logilab.org/ticket/103668
+	sed -i \
+		-e 's:MANDIR=$(PREFIX)/man:MANDIR=$(PREFIX)/share/man:' \
+		-e 's:$(INSTALL) $$i:$(INSTALL) -m 644 $$i:' \
+		doc/Makefile || die
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# Install Mercurial extension config file
+	insinto /etc/mercurial/hgrc.d
+	doins hgext/hgview.rc
+}