Version bump for Gnome 3.14.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 87 insertions, 1 deletions

diff --git a/dev-vcs/gitg/ChangeLog b/dev-vcs/gitg/ChangeLog
index a824a10a8674..9ce5f7efc90a 100644
--- a/dev-vcs/gitg/ChangeLog
+++ b/dev-vcs/gitg/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-vcs/gitg
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitg/ChangeLog,v 1.32 2014/12/01 12:39:48 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitg/ChangeLog,v 1.33 2014/12/24 00:26:48 eva Exp $
+
+*gitg-3.14.1 (24 Dec 2014)
+
+  24 Dec 2014; Gilles Dartiguelongue <eva@gentoo.org> +gitg-3.14.1.ebuild:
+  Version bump for Gnome 3.14.
 
   01 Dec 2014; Michał Górny <mgorny@gentoo.org> gitg-3.14.0.ebuild:
   Add a proper REQUIRED_USE for libpeas compatibility, use python_setup() to use
diff --git a/dev-vcs/gitg/gitg-3.14.1.ebuild b/dev-vcs/gitg/gitg-3.14.1.ebuild
new file mode 100644
index 000000000000..2c4bfee7daa4
--- /dev/null
+++ b/dev-vcs/gitg/gitg-3.14.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitg/gitg-3.14.1.ebuild,v 1.1 2014/12/24 00:26:48 eva Exp $
+
+EAPI=5
+
+VALA_MIN_API_VERSION="0.20"
+PYTHON_COMPAT=( python{3_3,3_4} )
+
+inherit autotools gnome2 python-r1 vala
+
+DESCRIPTION="git repository viewer for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gitg"
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug glade +python"
+
+REQUIRED_USE="python? ( ^^ ( $(python_gen_useflags '*') ) )"
+
+# test if unbundling of libgd is possible
+# Currently it seems not to be (unstable API/ABI)
+RDEPEND="
+	dev-libs/libgee:0.8[introspection]
+	>=dev-libs/json-glib-0.16
+	>=app-text/gtkspell-3.0.3:3
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/gobject-introspection-0.10.1
+	dev-libs/libgit2[threads]
+	>=dev-libs/libgit2-glib-0.0.20
+	>=dev-libs/libpeas-1.5.0[gtk]
+	>=gnome-base/gsettings-desktop-schemas-0.1.1
+	>=net-libs/webkit-gtk-2.2:4[introspection]
+	>=x11-libs/gtk+-3.12.0:3
+	>=x11-libs/gtksourceview-3.10:3.0
+	>=x11-themes/gnome-icon-theme-symbolic-3.10
+	glade? ( >=dev-util/glade-3.2:3.10 )
+	python? (
+		${PYTHON_DEPS}
+		dev-libs/libpeas[python,${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	dev-libs/libgit2-glib[vala]
+	gnome-base/gnome-common
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+	>=dev-util/intltool-0.40
+	$(vala_depend)"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+pkg_setup() {
+	use python && [[ ${MERGE_TYPE} != binary ]] && python_setup
+}
+
+src_prepare() {
+	sed \
+		-e '/CFLAGS/s:-g::g' \
+		-e '/CFLAGS/s:-O0::g' \
+		-i configure.ac || die
+	eautoreconf
+	gnome2_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--disable-deprecations \
+		--disable-dependency-tracking \
+		$(use_enable debug) \
+		$(use_enable glade glade-catalog) \
+		$(use_enable python)
+}
+
+src_install() {
+	gnome2_src_install -j1
+}