Initial commit, ebuild by me. Closes bug #223743. With thanks to Mr_Bones & nyhm for review comments.

(Portage version: 2.1.6/cvs/Linux 2.6.28-rc8-00001-g6c34bc2-dirty x86_64)

1 files changed, 47 insertions, 0 deletions

diff --git a/games-arcade/opentyrian/opentyrian-20081211.ebuild b/games-arcade/opentyrian/opentyrian-20081211.ebuild
new file mode 100644
index 000000000000..edced97879cf
--- /dev/null
+++ b/games-arcade/opentyrian/opentyrian-20081211.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-arcade/opentyrian/opentyrian-20081211.ebuild,v 1.1 2008/12/12 14:22:46 chainsaw Exp $
+
+inherit eutils games
+
+DESCRIPTION="Open-source port of the DOS game Tyrian, vertical scrolling shooter"
+HOMEPAGE="http://code.google.com/p/opentyrian/"
+SRC_URI="http://darklomax.org/tyrian/tyrian21.zip
+	 mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug"
+
+RDEPEND="media-libs/libsdl
+	media-libs/sdl-net"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	dev-util/subversion"
+
+S=${WORKDIR}/${PN}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}/${PV}-datapath.diff"
+	if  ! use debug; then
+		sed -i -e "s@DEBUG := 1@DEBUG := 0@" "${S}/Makefile" || die "sed failed"
+	fi
+}
+
+src_compile() {
+	emake DATA_PATH="${GAMES_DATADIR}/${PN}" || die "Compilation failed"
+}
+
+src_install() {
+	dogamesbin tyrian || die "Failed to install game binary"
+	dodoc CREDITS NEWS README || die "Failed to install documentation"
+	domenu opentyrian.desktop || die "Failed to install desktop file"
+	doicon tyrian.xpm || die "Failed to install program icon"
+	insinto "${GAMES_DATADIR}/${PN}"
+	cd "${WORKDIR}/tyrian21"
+	doins * || die "Failed to install game data"
+	prepgamesdirs
+}