version bump

(Portage version: 2.1.4.4)

2 files changed, 103 insertions, 1 deletions

diff --git a/games-strategy/triplea/ChangeLog b/games-strategy/triplea/ChangeLog
index fc4306e23e35..09394de81030 100644
--- a/games-strategy/triplea/ChangeLog
+++ b/games-strategy/triplea/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for games-strategy/triplea
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/triplea/ChangeLog,v 1.38 2008/01/10 23:14:02 caster Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/triplea/ChangeLog,v 1.39 2008/06/16 04:55:00 mr_bones_ Exp $
+
+*triplea-1.0.0.2 (16 Jun 2008)
+
+  16 Jun 2008; Michael Sterrett <mr_bones_@gentoo.org>
+  +triplea-1.0.0.2.ebuild:
+  version bump
 
   10 Jan 2008; Vlastimil Babka <caster@gentoo.org>
   triplea-0.9.0.2-r1.ebuild:
diff --git a/games-strategy/triplea/triplea-1.0.0.2.ebuild b/games-strategy/triplea/triplea-1.0.0.2.ebuild
new file mode 100644
index 000000000000..96308957db79
--- /dev/null
+++ b/games-strategy/triplea/triplea-1.0.0.2.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/triplea/triplea-1.0.0.2.ebuild,v 1.1 2008/06/16 04:55:00 mr_bones_ Exp $
+
+inherit eutils java-pkg-2 java-ant-2 versionator games
+
+MY_PV=$(replace_all_version_separators _)
+DESCRIPTION="An open source clone of the popular Axis and Allies boardgame"
+HOMEPAGE="http://triplea.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}_${MY_PV}_source_code_only.zip"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND="=dev-java/jgoodies-looks-2*
+	=dev-java/commons-httpclient-3*
+	dev-java/apple-java-extensions-bin
+	dev-java/commons-logging
+	dev-java/commons-codec
+	=dev-java/junit-3.8*"
+DEPEND="${RDEPEND}
+	>=virtual/jdk-1.5
+	app-arch/unzip"
+RDEPEND="${RDEPEND}
+	>=virtual/jre-1.5"
+
+S=${WORKDIR}/${PN}_${MY_PV}
+
+pkg_setup() {
+	games_pkg_setup
+	java-pkg-2_pkg_setup
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	sed -i \
+		-e 's/getWindows/getMyWindows/' \
+		src/games/strategy/debug/Console.java \
+		|| die "sed Console.java failed"
+
+	sed -i \
+		-e 's:/triplea/:/.triplea/:' \
+		src/games/strategy/engine/framework/ui/SaveGameFileChooser.java \
+		|| die "sed SaveGameFileChooser.java failed"
+
+	rm -f lib/{junit.jar,derby_10_1_2.jar,looks-2.1.4.jar,AppleJavaExtensions.jar}
+	java-pkg_jar-from jgoodies-looks-2.0 looks.jar lib/looks-2.1.4.jar
+	java-pkg_jar-from apple-java-extensions-bin AppleJavaExtensions.jar \
+		lib/AppleJavaExtensions.jar
+	java-pkg_jar-from commons-httpclient-3 commons-httpclient.jar \
+		lib/commons-httpclient-3.0.1.jar
+	java-pkg_jar-from commons-logging commons-logging.jar \
+		lib/commons-logging-1.1.jar
+	java-pkg_jar-from commons-codec commons-codec.jar \
+		lib/commons-codec-1.3.jar
+	# installs the test files
+	java-pkg_jar-from --into lib junit
+	java-pkg_ensure-no-bundled-jars
+}
+
+src_compile() {
+	eant || die
+	echo "triplea.saveGamesInHomeDir=true" > classes/triplea.properties
+	# The only target creating this is zip which does unjar etc
+	mkdir bin
+	cd classes
+	jar cf ../bin/triplea.jar * || die
+	rm -fr * || die
+}
+
+# Needs X11 maybe use virtualx.eclass
+RESTRICT="test"
+src_test() {
+	ANT_TASKS="ant-junit" eant test
+}
+
+src_install() {
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins -r bin data games images maps || die "doins failed"
+
+	java-pkg_regjar "${D}/${GAMES_DATADIR}"/${PN}/bin/*.jar
+	# TODO: add server launcher (see run-server.sh)
+	java-pkg_dolauncher ${PN} -into "${GAMES_PREFIX}" --main \
+		games.strategy.engine.framework.GameRunner
+
+	newicon data/games/strategy/engine/framework/ta_icon.png ${PN}.png
+	make_desktop_entry ${PN} TripleA
+
+	dodoc changelog.txt || die
+	dohtml -r doc/* readme.html || die
+	prepgamesdirs
+}