Bump to 3.0.2, from gnome overlay for GNOME 3, remove old.

(Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

4 files changed, 125 insertions, 88 deletions

diff --git a/gnome-base/gnome-control-center/ChangeLog b/gnome-base/gnome-control-center/ChangeLog
index fb6d92e75099..3e89c07fd32f 100644
--- a/gnome-base/gnome-control-center/ChangeLog
+++ b/gnome-base/gnome-control-center/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-base/gnome-control-center
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-control-center/ChangeLog,v 1.87 2011/04/30 17:40:48 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-control-center/ChangeLog,v 1.88 2011/08/18 06:22:02 nirbheek Exp $
+
+*gnome-control-center-3.0.2-r2 (18 Aug 2011)
+
+  18 Aug 2011; Nirbheek Chauhan <nirbheek@gentoo.org>
+  -gnome-control-center-2.32.1.ebuild, +gnome-control-center-3.0.2-r2.ebuild,
+  metadata.xml:
+  Bump to 3.0.2, from gnome overlay for GNOME 3, remove old.
 
   30 Apr 2011; Raúl Porcel <armin76@gentoo.org>
   gnome-control-center-2.32.1-r1.ebuild:
diff --git a/gnome-base/gnome-control-center/gnome-control-center-2.32.1.ebuild b/gnome-base/gnome-control-center/gnome-control-center-2.32.1.ebuild
deleted file mode 100644
index 7ddf3970e16f..000000000000
--- a/gnome-base/gnome-control-center/gnome-control-center-2.32.1.ebuild
+++ /dev/null
@@ -1,86 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-control-center/gnome-control-center-2.32.1.ebuild,v 1.9 2011/04/07 15:43:19 nirbheek Exp $
-
-EAPI="3"
-GCONF_DEBUG="yes"
-
-inherit gnome2
-
-DESCRIPTION="The gnome2 Desktop configuration tool"
-HOMEPAGE="http://www.gnome.org/"
-
-LICENSE="GPL-2"
-SLOT="2"
-KEYWORDS="alpha amd64 arm ia64 ppc ppc64 sh sparc x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
-IUSE="eds"
-
-# TODO: appindicator
-# libgnomekbd-2.91 breaks API/ABI
-RDEPEND="x11-libs/libXft
-	>=x11-libs/libXi-1.2
-	>=x11-libs/gtk+-2.20:2
-	>=dev-libs/glib-2.17.4:2
-	>=gnome-base/gconf-2.0:2
-	>=gnome-base/librsvg-2.0:2
-	>=gnome-base/nautilus-2.6
-	>=media-libs/fontconfig-1
-	>=dev-libs/dbus-glib-0.73
-	>=x11-libs/libxklavier-4.0
-	>=x11-wm/metacity-2.23.1
-	>=gnome-base/libgnomekbd-2.31.2
-	<gnome-base/libgnomekbd-2.91.0
-	>=gnome-base/gnome-desktop-2.29.4:2
-	>=gnome-base/gnome-menus-2.11.1
-	gnome-base/gnome-settings-daemon
-
-	dev-libs/libunique:1
-	x11-libs/pango
-	dev-libs/libxml2
-	media-libs/freetype
-	media-libs/libcanberra[gtk]
-
-	eds? ( >=gnome-extra/evolution-data-server-1.7.90 )
-
-	x11-apps/xmodmap
-	x11-libs/libXScrnSaver
-	x11-libs/libXext
-	x11-libs/libX11
-	x11-libs/libXxf86misc
-	x11-libs/libXrandr
-	x11-libs/libXrender
-	x11-libs/libXcursor"
-DEPEND="${RDEPEND}
-	x11-proto/scrnsaverproto
-	x11-proto/xextproto
-	x11-proto/xproto
-	x11-proto/xf86miscproto
-	x11-proto/kbproto
-	x11-proto/randrproto
-	x11-proto/renderproto
-
-	sys-devel/gettext
-	>=dev-util/intltool-0.40
-	>=dev-util/pkgconfig-0.19
-	dev-util/desktop-file-utils
-
-	app-text/scrollkeeper
-	>=app-text/gnome-doc-utils-0.10.1"
-# Needed for autoreconf
-#	gnome-base/gnome-common
-
-pkg_setup() {
-	G2CONF="${G2CONF}
-		--disable-update-mimedb
-		--disable-static
-		--disable-appindicator
-		$(use_enable eds aboutme)"
-	DOCS="AUTHORS ChangeLog NEWS README TODO"
-}
-
-src_install() {
-	gnome2_src_install
-	# gmodule is used to load plugins
-	# (on POSIX systems gmodule uses dlopen)
-	find "${ED}" -name "*.la" -delete || die "remove of la files failed"
-}
diff --git a/gnome-base/gnome-control-center/gnome-control-center-3.0.2-r2.ebuild b/gnome-base/gnome-control-center/gnome-control-center-3.0.2-r2.ebuild
new file mode 100644
index 000000000000..4af751e57565
--- /dev/null
+++ b/gnome-base/gnome-control-center/gnome-control-center-3.0.2-r2.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-control-center/gnome-control-center-3.0.2-r2.ebuild,v 1.1 2011/08/18 06:22:02 nirbheek Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes" # gmodule is used, which uses dlopen
+
+inherit gnome2
+
+DESCRIPTION="GNOME Desktop Configuration Tool"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2"
+SLOT="2"
+IUSE="+cheese +cups +networkmanager +socialweb"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
+
+# XXX: gnome-desktop-2.91.5 is needed for upstream commit c67f7efb
+# XXX: NetworkManager-0.9 support is automagic, make hard-dep once it's released
+#
+# gnome-session-2.91.6-r1 is needed so that 10-user-dirs-update is run at login
+# Latest gsettings-desktop-schemas is needed for commit 73f9bffb
+COMMON_DEPEND="
+	>=dev-libs/glib-2.25.11:2
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=x11-libs/gtk+-3.0.2:3
+	>=gnome-base/gsettings-desktop-schemas-2.91.92
+	>=gnome-base/gconf-2.0:2
+	>=dev-libs/dbus-glib-0.73
+	>=gnome-base/gnome-desktop-2.91.5:3
+	>=gnome-base/gnome-settings-daemon-2.91.94
+	>=gnome-base/libgnomekbd-2.91.91
+
+	app-text/iso-codes
+	dev-libs/libxml2:2
+	gnome-base/gnome-menus
+	gnome-base/libgtop:2
+	media-libs/fontconfig
+
+	>=media-libs/libcanberra-0.13[gtk3]
+	>=media-sound/pulseaudio-0.9.16[glib]
+	>=sys-auth/polkit-0.97
+	>=sys-power/upower-0.9.1
+
+	x11-apps/xmodmap
+	x11-libs/libX11
+	x11-libs/libXxf86misc
+	>=x11-libs/libxklavier-5.1
+	>=x11-libs/libXi-1.2
+
+	cheese? (
+		media-libs/gstreamer:0.10
+		>=media-video/cheese-2.91.91.1 )
+	cups? ( >=net-print/cups-1.4[dbus] )
+	networkmanager? ( >=net-misc/networkmanager-0.8.997 )
+	socialweb? ( net-libs/libsocialweb )"
+RDEPEND="${COMMON_DEPEND}
+	sys-apps/accountsservice
+	cups? ( net-print/cups-pk-helper )
+
+	!gnome-extra/gnome-media[pulseaudio]
+	!<gnome-extra/gnome-media-2.32.0-r300
+	!<gnome-base/gdm-2.91.94"
+# PDEPEND to avoid circular dependency
+PDEPEND=">=gnome-base/gnome-session-2.91.6-r1"
+DEPEND="${COMMON_DEPEND}
+	x11-proto/xproto
+	x11-proto/xf86miscproto
+	x11-proto/kbproto
+
+	>=sys-devel/gettext-0.17
+	>=dev-util/intltool-0.40.1
+	>=dev-util/pkgconfig-0.19
+
+	app-text/scrollkeeper
+	>=app-text/gnome-doc-utils-0.10.1
+
+	cups? ( sys-apps/sed )"
+# Needed for autoreconf
+#	gnome-base/gnome-common
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-update-mimedb
+		--disable-static
+		--disable-maintainer-mode
+		$(use_with cheese)
+		$(use_enable cups)
+		$(use_with socialweb libsocialweb)"
+	DOCS="AUTHORS ChangeLog NEWS README TODO"
+}
+
+src_prepare() {
+	# https://bugzilla.gnome.org/show_bug.cgi?id=651162
+	# XXX: remove for next release
+	sed -e 's:no-undefined:-no-undefined:' \
+		-i libgnome-control-center/Makefile.* || die "sed failed"
+
+	# cups-1.5 compatibility; will be in next release
+	epatch "${FILESDIR}/${P}-cups-ppd.h.patch"
+
+	# https://bugzilla.gnome.org/show_bug.cgi?id=653211, will be in next release
+	epatch "${FILESDIR}/${P}-https-handler.patch"
+
+	# fix deleting users on 32-bit systems, will be in next release
+	epatch "${FILESDIR}/${P}-delete-users-32-bit.patch"
+
+	gnome2_src_prepare
+}
diff --git a/gnome-base/gnome-control-center/metadata.xml b/gnome-base/gnome-control-center/metadata.xml
index da6fd63d0085..ef86235e8846 100644
--- a/gnome-base/gnome-control-center/metadata.xml
+++ b/gnome-base/gnome-control-center/metadata.xml
@@ -1,5 +1,11 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>gnome</herd>
+	<herd>gnome</herd>
+	<use>
+		<flag name="cheese">Add support for taking pictures for the user
+			accounts panel using <pkg>media-video/cheese</pkg></flag>
+		<flag name="socialweb">Add support for configuring social web service
+			settings using <pkg>net-libs/libsocialweb</pkg></flag>
+	</use>
 </pkgmetadata>