[kde-base] Add KDE SC 4.7.1

(Portage version: 2.2.0_alpha54/cvs/Linux x86_64)

2 files changed, 82 insertions, 1 deletions

diff --git a/kde-base/kdepimlibs/ChangeLog b/kde-base/kdepimlibs/ChangeLog
index 1ba184ca156e..99bb2f183adb 100644
--- a/kde-base/kdepimlibs/ChangeLog
+++ b/kde-base/kdepimlibs/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kdepimlibs
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/ChangeLog,v 1.110 2011/08/15 18:43:07 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/ChangeLog,v 1.111 2011/09/07 20:13:48 alexxy Exp $
+
+*kdepimlibs-4.7.1 (07 Sep 2011)
+
+  07 Sep 2011; Alexey Shvetsov <alexxy@gentoo.org> +kdepimlibs-4.7.1.ebuild:
+  Version bump KDE SC 4.7.1
 
   15 Aug 2011; Markus Meier <maekke@gentoo.org> kdepimlibs-4.6.5.ebuild:
   x86 stable, bug #377465
diff --git a/kde-base/kdepimlibs/kdepimlibs-4.7.1.ebuild b/kde-base/kdepimlibs/kdepimlibs-4.7.1.ebuild
new file mode 100644
index 000000000000..33c4ff0e985c
--- /dev/null
+++ b/kde-base/kdepimlibs/kdepimlibs-4.7.1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/kdepimlibs-4.7.1.ebuild,v 1.1 2011/09/07 20:13:48 alexxy Exp $
+
+EAPI=4
+
+KDE_HANDBOOK="optional"
+CPPUNIT_REQUIRED="optional"
+KDE_SCM="git"
+inherit kde4-base
+
+DESCRIPTION="Common library for KDE PIM apps."
+HOMEPAGE="http://www.kde.org/"
+
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+LICENSE="LGPL-2.1"
+IUSE="debug ldap semantic-desktop"
+
+# some akonadi tests timeout, that probaly needs more work as its ~700 tests
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=app-crypt/gpgme-1.1.6
+	dev-libs/libgpg-error
+	>=dev-libs/libical-0.43
+	dev-libs/cyrus-sasl
+	$(add_kdebase_dep kdelibs 'semantic-desktop=')
+	semantic-desktop? (
+		>=app-office/akonadi-server-1.5.80
+		media-libs/phonon
+		x11-misc/shared-mime-info
+	)
+	ldap? ( net-nds/openldap )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.35.0-r5
+"
+RDEPEND="${COMMON_DEPEND}"
+
+# libakonadi-kcal moved here from akonadi in 4.3.86
+add_blocker akonadi '<4.3.86'
+# @since 4.3 - libkholidays is in kdepimlibs now
+add_blocker libkholidays
+# @since 4.4 - kontactinterfaces is in kdepimlibs now
+add_blocker kontactinterfaces
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	# Disable hardcoded checks
+	sed -r -e '/find_package\((Akonadi|SharedDesktopOntologies|Soprano|Nepomuk)/{/macro_optional_/!s/find/macro_optional_&/}' \
+		-e '/macro_log_feature\((Akonadi|SHAREDDESKTOPONTOLOGIES|Soprano|Nepomuk)_FOUND/s/ TRUE / FALSE /' \
+		-e '/add_subdirectory\((akonadi|mailtransport)/{/macro_optional_/!s/add/macro_optional_&/}' \
+		-i CMakeLists.txt || die
+	if ! use semantic-desktop; then
+		sed -e '/include(SopranoAddOntology)/s/^/#DISABLED /' \
+			-i CMakeLists.txt || die
+		# More reliable than -DBUILD_akonadi=OFF
+		rm -r akonadi mailtransport || die
+	fi
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build handbook doc)
+		$(cmake-utils_use_with ldap)
+		$(cmake-utils_use_with semantic-desktop Akonadi)
+		$(cmake-utils_use_with semantic-desktop SharedDesktopOntologies)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+		# $(cmake-utils_use_with prison)
+		-DWITH_Prison=NO
+	)
+
+	kde4-base_src_configure
+}