Revision bump to default to ruby20.

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key )

2 files changed, 67 insertions, 1 deletions

diff --git a/kde-base/krossruby/ChangeLog b/kde-base/krossruby/ChangeLog
index 40df5e044fc5..3fa85097e69a 100644
--- a/kde-base/krossruby/ChangeLog
+++ b/kde-base/krossruby/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/krossruby
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/krossruby/ChangeLog,v 1.187 2014/11/16 12:21:28 alexxy Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/krossruby/ChangeLog,v 1.188 2014/12/02 13:09:10 mrueg Exp $
+
+*krossruby-4.14.3-r1 (02 Dec 2014)
+
+  02 Dec 2014; Manuel Rüger <mrueg@gentoo.org> +krossruby-4.14.3-r1.ebuild:
+  Revision bump to default to ruby20.
 
 *krossruby-4.14.3 (16 Nov 2014)
 
diff --git a/kde-base/krossruby/krossruby-4.14.3-r1.ebuild b/kde-base/krossruby/krossruby-4.14.3-r1.ebuild
new file mode 100644
index 000000000000..fe7408fdb54b
--- /dev/null
+++ b/kde-base/krossruby/krossruby-4.14.3-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/krossruby/krossruby-4.14.3-r1.ebuild,v 1.1 2014/12/02 13:09:10 mrueg Exp $
+
+EAPI=5
+
+KMNAME="kross-interpreters"
+KMMODULE="ruby"
+
+USE_RUBY="ruby20"
+# Only one ruby version is supported:
+# 1) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
+# 2) the ebuild can only be installed for one ruby variant, otherwise the compiled
+#    files with identical path+name will overwrite each other - difficult :(
+
+inherit kde4-meta ruby-ng
+
+DESCRIPTION="Kross scripting framework: Ruby interpreter"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND=""
+RDEPEND=""
+
+pkg_setup() {
+	ruby-ng_pkg_setup
+	kde4-meta_pkg_setup
+}
+
+src_unpack() {
+	local S="${WORKDIR}/${P}"
+	kde4-meta_src_unpack
+
+	cd "${WORKDIR}"
+	mkdir all
+	mv ${P} all/ || die "Could not move sources"
+}
+
+all_ruby_prepare() {
+	kde4-meta_src_prepare
+}
+
+each_ruby_configure() {
+	local CMAKE_USE_DIR=${S}
+	local mycmakeargs=(
+		-DRUBY_LIBRARY=$(ruby_get_libruby)
+		-DRUBY_INCLUDE_DIR=$(ruby_get_hdrdir)
+		-DRUBY_EXECUTABLE=${RUBY}
+	)
+	kde4-meta_src_configure
+}
+
+each_ruby_compile() {
+	local CMAKE_USE_DIR=${S}
+	kde4-meta_src_compile
+}
+
+each_ruby_install() {
+	local CMAKE_USE_DIR=${S}
+	kde4-meta_src_install
+}