[kde-base] Add KDE SC 4.6.0

(Portage version: 2.2.0_alpha19_p2/cvs/Linux x86_64, RepoMan options: --force)

1 files changed, 91 insertions, 0 deletions

diff --git a/kde-base/systemsettings/systemsettings-4.6.0.ebuild b/kde-base/systemsettings/systemsettings-4.6.0.ebuild
new file mode 100644
index 000000000000..c8a2c0cd9528
--- /dev/null
+++ b/kde-base/systemsettings/systemsettings-4.6.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/systemsettings-4.6.0.ebuild,v 1.1 2011/01/26 20:29:18 alexxy Exp $
+
+EAPI="3"
+
+KDE_HANDBOOK="optional"
+KMNAME="kdebase-workspace"
+OPENGL_REQUIRED="optional"
+inherit kde4-meta
+
+DESCRIPTION="System settings utility"
+IUSE="debug +usb xinerama"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+
+COMMONDEPEND="
+	dev-libs/glib:2
+	$(add_kdebase_dep libkworkspace)
+	media-libs/fontconfig
+	>=media-libs/freetype-2
+	>=x11-libs/libxklavier-3.2
+	x11-libs/libXcursor
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXft
+	x11-libs/libXrandr
+	x11-libs/libXtst
+	opengl? ( virtual/opengl )
+	usb? ( =virtual/libusb-0* )
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="${COMMONDEPEND}
+	x11-proto/kbproto
+	x11-proto/xextproto
+	xinerama? ( x11-proto/xineramaproto )
+"
+RDEPEND="${COMMONDEPEND}
+	sys-libs/timezone-data
+	x11-apps/setxkbmap
+	x11-misc/xkeyboard-config
+"
+
+KMEXTRA="
+	kcontrol/
+"
+KMEXTRACTONLY="
+	krunner/dbus/org.kde.krunner.App.xml
+	krunner/dbus/org.kde.screensaver.xml
+	kwin/
+	libs/
+	plasma/
+"
+
+add_blocker kcontrol '<4.3.98'
+add_blocker konqueror '<4.4.70'
+
+PATCHES=( "${FILESDIR}/${PN}-4.4.2-xinerama_cmake_automagic.patch" )
+
+src_unpack() {
+	if use handbook; then
+		KMEXTRA+="
+			doc/kcontrol
+			doc/kfontview
+		"
+	fi
+
+	kde4-meta_src_unpack
+}
+
+src_prepare() {
+	sed -i -e 's/systemsettingsrc DESTINATION ${SYSCONF_INSTALL_DIR}/systemsettingsrc DESTINATION ${CONFIG_INSTALL_DIR}/' \
+		systemsettings/CMakeLists.txt \
+		|| die "Failed to fix systemsettingsrc install location"
+
+	kde4-meta_src_prepare
+}
+
+# FIXME: is have_openglxvisual found without screensaver
+src_configure() {
+	# Old keyboard-detection code is unmaintained,
+	# so we force the new stuff, using libxklavier.
+	mycmakeargs=(
+		-DUSE_XKLAVIER=ON -DWITH_LibXKlavier=ON
+		-DWITH_GLIB2=ON -DWITH_GObject=ON
+		$(cmake-utils_use_with opengl OpenGL)
+		$(cmake-utils_use_with usb)
+		$(cmake-utils_use_with xinerama X11_Xinerama)
+	)
+
+	kde4-meta_src_configure
+}