LXQt 0.9.0 version bump

(Portage version: 2.2.16/cvs/Linux x86_64, signed Manifest commit with key 0x4FDF9CFD2FAC514E!)

2 files changed, 78 insertions, 1 deletions

diff --git a/lxqt-base/lxqt-panel/ChangeLog b/lxqt-base/lxqt-panel/ChangeLog
index 70ac4b8af6d4..7adc1af19130 100644
--- a/lxqt-base/lxqt-panel/ChangeLog
+++ b/lxqt-base/lxqt-panel/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for lxqt-base/lxqt-panel
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/lxqt-base/lxqt-panel/ChangeLog,v 1.10 2015/01/30 16:32:19 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/lxqt-base/lxqt-panel/ChangeLog,v 1.11 2015/02/10 17:12:23 yngwin Exp $
+
+*lxqt-panel-0.9.0 (10 Feb 2015)
+
+  10 Feb 2015; Ben de Groot <yngwin@gentoo.org> +lxqt-panel-0.9.0.ebuild:
+  LXQt 0.9.0 version bump
 
   30 Jan 2015; Michael Palimaka <kensington@gentoo.org>
   lxqt-panel-0.7.0-r1.ebuild, lxqt-panel-0.8.0.ebuild:
diff --git a/lxqt-base/lxqt-panel/lxqt-panel-0.9.0.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-0.9.0.ebuild
new file mode 100644
index 000000000000..4c16516e304e
--- /dev/null
+++ b/lxqt-base/lxqt-panel/lxqt-panel-0.9.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/lxqt-base/lxqt-panel/lxqt-panel-0.9.0.ebuild,v 1.1 2015/02/10 17:12:23 yngwin Exp $
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt desktop panel and plugins"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="http://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+IUSE="+alsa +clock colorpicker cpuload +desktopswitch dom +kbindicator +mainmenu
+	+mount networkmonitor pulseaudio +quicklaunch screensaver sensors
+	+showdesktop sysstat +taskbar +tray +volume worldclock"
+REQUIRED_USE="volume? ( || ( alsa pulseaudio ) )"
+
+DEPEND="
+	>=dev-libs/libqtxdg-1.0.0
+	dev-qt/linguist-tools:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kguiaddons:5
+	kde-frameworks/kwindowsystem:5
+	>=lxde-base/menu-cache-0.3.3
+	~lxqt-base/liblxqt-${PV}
+	~lxqt-base/liblxqt-mount-${PV}
+	~lxqt-base/lxqt-globalkeys-${PV}
+	x11-libs/libX11
+	cpuload? ( sys-libs/libstatgrab )
+	networkmonitor? ( sys-libs/libstatgrab )
+	sensors? ( sys-apps/lm_sensors )
+	sysstat? ( =lxqt-base/libsysstat-0.3* )
+	volume? ( alsa? ( media-libs/alsa-lib )
+		pulseaudio? ( media-sound/pulseaudio ) )"
+RDEPEND="${DEPEND}
+	dev-qt/qtsvg:5
+	>=lxde-base/lxmenu-data-0.1.2"
+
+src_configure() {
+	local mycmakeargs i y
+	for i in clock colorpicker cpuload desktopswitch dom kbindicator mainmenu mount \
+		networkmonitor quicklaunch screensaver sensors showdesktop sysstat \
+		taskbar tray volume worldclock; do
+		y=$(tr '[:lower:]' '[:upper:]' <<< "${i}")
+		mycmakeargs+=( $(cmake-utils_use ${i} ${y}_PLUGIN) )
+	done
+
+	if use volume; then
+		mycmakeargs+=( $(cmake-utils_use alsa VOLUME_USE_ALSA)
+			$(cmake-utils_use pulseaudio VOLUME_USE_PULSEAUDIO) )
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_install(){
+	cmake-utils_src_install
+	doman panel/man/*.1
+}