add CMake based ebuild, using EAPI=5, should fix bug #476836 and bug #460274

(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 072AD062)

2 files changed, 79 insertions, 1 deletions

diff --git a/media-gfx/enblend/ChangeLog b/media-gfx/enblend/ChangeLog
index 0b0d665f7889..0b0d207fbfdf 100644
--- a/media-gfx/enblend/ChangeLog
+++ b/media-gfx/enblend/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/enblend
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/enblend/ChangeLog,v 1.53 2013/05/08 08:50:30 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/enblend/ChangeLog,v 1.54 2013/09/06 20:48:55 maekke Exp $
+
+*enblend-4.1.1-r1 (06 Sep 2013)
+
+  06 Sep 2013; Markus Meier <maekke@gentoo.org> +enblend-4.1.1-r1.ebuild:
+  add CMake based ebuild, using EAPI=5, should fix bug #476836 and bug #460274
 
   08 May 2013; Tim Harder <radhermit@gentoo.org> -enblend-4.0.ebuild,
   -files/enblend-4.0-libpng14.patch, -files/enblend-4.0-libpng15.patch,
diff --git a/media-gfx/enblend/enblend-4.1.1-r1.ebuild b/media-gfx/enblend/enblend-4.1.1-r1.ebuild
new file mode 100644
index 000000000000..72eae60f62d5
--- /dev/null
+++ b/media-gfx/enblend/enblend-4.1.1-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/enblend/enblend-4.1.1-r1.ebuild,v 1.1 2013/09/06 20:48:55 maekke Exp $
+
+EAPI=5
+
+inherit cmake-utils
+
+MY_P="${PN}-enfuse-${PV/_rc/rc}"
+
+DESCRIPTION="Image Blending with Multiresolution Splines"
+HOMEPAGE="http://enblend.sourceforge.net/"
+SRC_URI="mirror://sourceforge/enblend/${MY_P}.tar.gz"
+
+LICENSE="GPL-2 VIGRA"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug doc gpu image-cache openmp"
+
+REQUIRED_USE="openmp? ( !image-cache )"
+
+RDEPEND="
+	media-libs/glew
+	=media-libs/lcms-2*
+	>=media-libs/libpng-1.2.43:0=
+	>=media-libs/openexr-1.0
+	media-libs/plotutils[X]
+	media-libs/tiff
+	>=media-libs/vigra-1.8.0
+	sci-libs/gsl
+	virtual/jpeg:0=
+	debug? ( dev-libs/dmalloc )
+	gpu? ( media-libs/freeglut )"
+DEPEND="${RDEPEND}
+	>=dev-libs/boost-1.31.0
+	virtual/pkgconfig
+	doc? (
+		media-gfx/imagemagick
+		media-gfx/transfig
+		sci-visualization/gnuplot[gd]
+		virtual/latex-base
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	sed -i -e "/CXX_FLAGS/s:-O3::g" CMakeLists.txt || die
+	sed -i -e "s:doc/enblend:doc/${P}:" doc/CMakeLists.txt || die
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_CXX_FLAGS_RELEASE=""
+		$(cmake-utils_use_enable debug DMALLOC)
+		$(cmake-utils_use doc DOC)
+		$(cmake-utils_use_enable image-cache IMAGECACHE)
+		$(cmake-utils_use_enable openmp)
+		$(cmake-utils_use_enable gpu OPENCL)
+	)
+	CMAKE_BUILD_TYPE="Release"
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	# forcing -j1 as every parallel compilation process needs about 1 GB RAM.
+	cmake-utils_src_compile -j1
+}
+
+src_install() {
+	local DOCS=( AUTHORS ChangeLog NEWS README )
+	cmake-utils_src_install
+}