Version bump.

(Portage version: 2.2.0_alpha136/cvs/Linux x86_64)

2 files changed, 66 insertions, 1 deletions

diff --git a/media-gfx/feh/ChangeLog b/media-gfx/feh/ChangeLog
index 147c0f823b31..68e6553e3e58 100644
--- a/media-gfx/feh/ChangeLog
+++ b/media-gfx/feh/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/feh
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/feh/ChangeLog,v 1.114 2012/09/27 21:51:14 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/feh/ChangeLog,v 1.115 2012/10/16 16:15:38 radhermit Exp $
+
+*feh-2.7 (16 Oct 2012)
+
+  16 Oct 2012; Tim Harder <radhermit@gentoo.org> +feh-2.7.ebuild:
+  Version bump.
 
 *feh-2.6.3 (27 Sep 2012)
 
diff --git a/media-gfx/feh/feh-2.7.ebuild b/media-gfx/feh/feh-2.7.ebuild
new file mode 100644
index 000000000000..075a6878b9db
--- /dev/null
+++ b/media-gfx/feh/feh-2.7.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/feh/feh-2.7.ebuild,v 1.1 2012/10/16 16:15:38 radhermit Exp $
+
+EAPI=4
+inherit eutils toolchain-funcs
+
+DESCRIPTION="A fast, lightweight imageviewer using imlib2"
+HOMEPAGE="http://feh.finalrewind.org/"
+SRC_URI="http://feh.finalrewind.org/${P}.tar.bz2"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="debug curl exif test xinerama"
+
+COMMON_DEPEND=">=media-libs/giblib-1.2.4
+	media-libs/imlib2
+	>=media-libs/libpng-1.2:0
+	x11-libs/libX11
+	curl? ( net-misc/curl )
+	exif? ( media-libs/libexif )
+	xinerama? ( x11-libs/libXinerama )"
+RDEPEND="${COMMON_DEPEND}
+	virtual/jpeg"
+DEPEND="${COMMON_DEPEND}
+	x11-libs/libXt
+	x11-proto/xproto
+	test? (
+		>=dev-lang/perl-5.10
+		dev-perl/Test-Command
+		)"
+
+pkg_setup() {
+	use_feh() { usex $1 1 0; }
+
+	fehopts=(
+		DESTDIR="${D}"
+		PREFIX=/usr
+		doc_dir='${main_dir}'/share/doc/${PF}
+		example_dir='${main_dir}'/share/doc/${PF}/examples
+		curl=$(use_feh curl)
+		debug=$(use_feh debug)
+		xinerama=$(use_feh xinerama)
+		exif=$(use_feh exif)
+		)
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.6.2-debug-cflags.patch
+}
+
+src_compile() {
+	tc-export CC
+	emake "${fehopts[@]}"
+}
+
+src_install() {
+	emake "${fehopts[@]}" install
+}