Version bump with gtk+3 fixes (but still disabled until ready for the tree), bump to EAPI3 and run elibtoolize only when required (as read on ChangeLog, only ~x86-fbsd needs it).

(Portage version: 2.1.9.14/cvs/Linux x86_64)

2 files changed, 69 insertions, 1 deletions

diff --git a/media-libs/libcanberra/ChangeLog b/media-libs/libcanberra/ChangeLog
index 9ce6b9d8d5d9..36e66e751e0a 100644
--- a/media-libs/libcanberra/ChangeLog
+++ b/media-libs/libcanberra/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/libcanberra
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v 1.55 2010/10/07 20:22:07 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v 1.56 2010/10/09 16:04:04 pacho Exp $
+
+*libcanberra-0.26 (09 Oct 2010)
+
+  09 Oct 2010; Pacho Ramos <pacho@gentoo.org> +libcanberra-0.26.ebuild:
+  Version bump with gtk+3 fixes (but still disabled until ready for the
+  tree), bump to EAPI3 and run elibtoolize only when required (as read on
+  ChangeLog, only ~x86-fbsd needs it).
 
   07 Oct 2010; Samuli Suominen <ssuominen@gentoo.org>
   libcanberra-0.25.ebuild:
diff --git a/media-libs/libcanberra/libcanberra-0.26.ebuild b/media-libs/libcanberra/libcanberra-0.26.ebuild
new file mode 100644
index 000000000000..8db889da4a03
--- /dev/null
+++ b/media-libs/libcanberra/libcanberra-0.26.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/libcanberra-0.26.ebuild,v 1.1 2010/10/09 16:04:02 pacho Exp $
+
+EAPI="3"
+inherit gnome2-utils libtool
+
+DESCRIPTION="Portable Sound Event Library"
+HOMEPAGE="http://0pointer.de/lennart/projects/libcanberra/"
+SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="alsa gstreamer +gtk oss pulseaudio +sound tdb"
+
+COMMON_DEPEND="media-libs/libvorbis
+	>=sys-devel/libtool-2.2.6b
+	alsa? ( media-libs/alsa-lib )
+	gstreamer? ( >=media-libs/gstreamer-0.10.15 )
+	gtk? ( >=x11-libs/gtk+-2.20.0:2
+		>=gnome-base/gconf-2 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.11 )
+	tdb? ( sys-libs/tdb )"
+RDEPEND="${COMMON_DEPEND}
+	sound? ( x11-themes/sound-theme-freedesktop )" # Required for index.theme wrt #323379
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/pkgconfig-0.17"
+
+src_prepare() {
+	# Run elibtoolize for ~x86-fbsd.
+	use x86-fbsd && elibtoolize
+}
+
+# --disable-gtk3 for now
+src_configure() {
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--disable-dependency-tracking \
+		$(use_enable alsa) \
+		$(use_enable oss) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable gstreamer) \
+		$(use_enable gtk) \
+		$(use_enable tdb) \
+		--disable-lynx \
+		--disable-gtk-doc \
+		--disable-gtk-doc-html \
+		--disable-gtk-doc-pdf \
+		--disable-gtk3 \
+		--with-html-dir=/usr/share/doc/${PF}/html
+}
+
+src_install() {
+	# Disable parallel installation until bug #253862 is solved
+	emake -j1 DESTDIR="${ED}" install || die
+	prepalldocs
+}
+
+pkg_preinst() { gnome2_gconf_savelist; }
+pkg_postinst() { gnome2_gconf_install; }