Bump to 0.10.0, new slot, ebuild from the GNOME overlay

(Portage version: 2.1.9.46/cvs/Linux x86_64)

3 files changed, 74 insertions, 3 deletions

diff --git a/media-libs/libchamplain/ChangeLog b/media-libs/libchamplain/ChangeLog
index 678de8bfc358..12e58f85e250 100644
--- a/media-libs/libchamplain/ChangeLog
+++ b/media-libs/libchamplain/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libchamplain
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libchamplain/ChangeLog,v 1.11 2011/03/31 13:27:02 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libchamplain/ChangeLog,v 1.12 2011/06/02 21:34:14 nirbheek Exp $
+
+*libchamplain-0.10.0 (02 Jun 2011)
+
+  02 Jun 2011; Nirbheek Chauhan <nirbheek@gentoo.org>
+  +libchamplain-0.10.0.ebuild:
+  Bump to 0.10.0, new slot, ebuild from the GNOME overlay
 
 *libchamplain-0.8.3 (31 Mar 2011)
 
diff --git a/media-libs/libchamplain/libchamplain-0.10.0.ebuild b/media-libs/libchamplain/libchamplain-0.10.0.ebuild
new file mode 100644
index 000000000000..28f6ee48d6f6
--- /dev/null
+++ b/media-libs/libchamplain/libchamplain-0.10.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libchamplain/libchamplain-0.10.0.ebuild,v 1.1 2011/06/02 21:34:14 nirbheek Exp $
+
+EAPI="4"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="Clutter based world map renderer"
+HOMEPAGE="http://blog.pierlux.com/projects/libchamplain/en/"
+
+LICENSE="LGPL-2"
+SLOT="0.10"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc +gtk +introspection vala"
+
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.16:2
+	>=x11-libs/cairo-1.4
+	>=media-libs/clutter-1.2:1.0[introspection?]
+	>=media-libs/memphis-0.2.1:0.2[introspection?]
+	>=net-libs/libsoup-gnome-2.4.1:2.4
+	dev-db/sqlite:3
+	gtk? (
+		>=x11-libs/gtk+-2.90:3[introspection?]
+		>=media-libs/clutter-gtk-0.90:1.0 )
+	introspection? ( >=dev-libs/gobject-introspection-0.6.3 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( >=dev-util/gtk-doc-1.9 )
+	vala? ( dev-lang/vala:0.12 )"
+
+pkg_setup() {
+	DOCS="AUTHORS ChangeLog NEWS README"
+	# Vala demos are only built, so just disable them
+	G2CONF="${G2CONF}
+		--disable-maintainer-mode
+		--disable-static
+		--disable-maemo
+		--disable-vala-demos
+		--enable-memphis
+		VAPIGEN=$(type -p vapigen-0.12)
+		$(use_enable debug)
+		$(use_enable gtk)
+		$(use_enable introspection)
+		$(use_enable vala)"
+}
+
+src_prepare() {
+	# Fix documentation slotability
+	sed -e "s/^DOC_MODULE.*/DOC_MODULE = ${PN}-${SLOT}/" \
+		-i docs/reference/Makefile.{am,in} || die "sed (1) failed"
+	sed -e "s/^DOC_MODULE.*/DOC_MODULE = ${PN}-gtk-${SLOT}/" \
+		-i docs/reference-gtk/Makefile.{am,in} || die "sed (2) failed"
+	mv "${S}"/docs/reference/${PN}{,-${SLOT}}-docs.sgml || die "mv (1) failed"
+	mv "${S}"/docs/reference-gtk/${PN}-gtk{,-${SLOT}}-docs.sgml || die "mv (1) failed"
+
+	gnome2_src_prepare
+}
diff --git a/media-libs/libchamplain/metadata.xml b/media-libs/libchamplain/metadata.xml
index c67117a37f18..eca07518f08f 100644
--- a/media-libs/libchamplain/metadata.xml
+++ b/media-libs/libchamplain/metadata.xml
@@ -5,7 +5,9 @@
   <email>jlec@gentoo.org</email>
 </maintainer>
 <use>
-  <flag name='introspection'>Use dev-libs/gobject-introspection for introspection</flag>
-  <flag name='html'>Install gtk-doc html version for this package</flag>
+	<flag name='introspection'>Use <pkg>dev-libs/gobject-introspection</pkg> for
+		introspection</flag>
+	<flag name='html'>Install gtk-doc html version for this package</flag>
+	<flag name='vala'>Generate bindings for <pkg>dev-lang/vala</pkg></flag>
 </use>
 </pkgmetadata>