Include <stdio.h> for type name "FILE" wrt #499480 by Andreas Proteus

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 files changed, 46 insertions, 0 deletions

diff --git a/media-libs/libmng/libmng-2.0.2-r1.ebuild b/media-libs/libmng/libmng-2.0.2-r1.ebuild
new file mode 100644
index 000000000000..92a5bf4d0ca8
--- /dev/null
+++ b/media-libs/libmng/libmng-2.0.2-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmng/libmng-2.0.2-r1.ebuild,v 1.1 2014/01/27 18:12:40 ssuominen Exp $
+
+EAPI=5
+inherit eutils autotools-multilib
+
+DESCRIPTION="Multiple Image Networkgraphics lib (animated png's)"
+HOMEPAGE="http://www.libmng.com/"
+SRC_URI="mirror://sourceforge/libmng/${P}.tar.xz"
+
+LICENSE="libmng"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="lcms static-libs"
+
+RDEPEND="virtual/jpeg:0[${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.1.4[${MULTILIB_USEDEP}]
+	lcms? ( media-libs/lcms:2[${MULTILIB_USEDEP}] )
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20130224-r5
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-stdio.patch
+	emake distclean
+	autotools-multilib_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		--with-jpeg
+		$(use_with lcms lcms2)
+		--without-lcms
+		)
+
+	autotools-multilib_src_configure
+}
+
+src_install() {
+	autotools-multilib_src_install
+
+	dodoc CHANGES README* doc/{doc.readme,libmng.txt}
+	doman doc/man/*.{3,5}
+}