Version bump.

(Portage version: 2.2.0_alpha87/cvs/Linux x86_64)

2 files changed, 62 insertions, 1 deletions

diff --git a/media-libs/libpng/ChangeLog b/media-libs/libpng/ChangeLog
index 73bfd85155e3..e1b9329d1fe1 100644
--- a/media-libs/libpng/ChangeLog
+++ b/media-libs/libpng/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libpng
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v 1.345 2012/02/06 20:00:18 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v 1.346 2012/02/19 09:36:32 radhermit Exp $
+
+*libpng-1.5.9 (19 Feb 2012)
+
+  19 Feb 2012; Tim Harder <radhermit@gentoo.org> +libpng-1.5.9.ebuild:
+  Version bump.
 
   06 Feb 2012; Samuli Suominen <ssuominen@gentoo.org> -libpng-1.5.6.ebuild,
   -libpng-1.5.7.ebuild:
diff --git a/media-libs/libpng/libpng-1.5.9.ebuild b/media-libs/libpng/libpng-1.5.9.ebuild
new file mode 100644
index 000000000000..9d95448937eb
--- /dev/null
+++ b/media-libs/libpng/libpng-1.5.9.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/libpng-1.5.9.ebuild,v 1.1 2012/02/19 09:36:32 radhermit Exp $
+
+# WARNING: media-gfx/optipng is shipping internal copy of libpng14. Look out for
+# security.
+
+EAPI=4
+
+inherit eutils libtool multilib
+
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
+	apng? ( mirror://sourceforge/${PN}-apng/${PN}-1.5.7-apng.patch.gz )"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="apng neon static-libs"
+
+RDEPEND="sys-libs/zlib"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils"
+
+DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
+
+src_prepare() {
+	if use apng; then
+		epatch "${WORKDIR}"/${PN}-1.5.7-apng.patch
+		# Don't execute symbols check with apng patch wrt #378111
+		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
+	fi
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable neon arm-neon)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}
+
+pkg_preinst() {
+	has_version ${CATEGORY}/${PN}:1.4 && return 0
+	preserve_old_lib /usr/$(get_libdir)/libpng14$(get_libname 14)
+}
+
+pkg_postinst() {
+	has_version ${CATEGORY}/${PN}:1.4 && return 0
+	preserve_old_lib_notify /usr/$(get_libdir)/libpng14$(get_libname 14)
+}