Version bump and update live ebuild.

(Portage version: 2.2.6/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

3 files changed, 119 insertions, 16 deletions

diff --git a/media-libs/libbluray/ChangeLog b/media-libs/libbluray/ChangeLog
index d179c1ac2708..cd9c8eea2218 100644
--- a/media-libs/libbluray/ChangeLog
+++ b/media-libs/libbluray/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libbluray
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/ChangeLog,v 1.51 2013/09/22 13:59:37 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/ChangeLog,v 1.52 2013/09/23 20:00:32 radhermit Exp $
+
+*libbluray-0.4.0 (23 Sep 2013)
+
+  23 Sep 2013; Tim Harder <radhermit@gentoo.org> +libbluray-0.4.0.ebuild,
+  libbluray-9999.ebuild:
+  Version bump and update live ebuild.
 
   22 Sep 2013; Luca Barbato <lu_zero@gentoo.org> libbluray-0.3.0-r1.ebuild,
   libbluray-9999.ebuild:
diff --git a/media-libs/libbluray/libbluray-0.4.0.ebuild b/media-libs/libbluray/libbluray-0.4.0.ebuild
new file mode 100644
index 000000000000..03cbbd6b1cb9
--- /dev/null
+++ b/media-libs/libbluray/libbluray-0.4.0.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/libbluray-0.4.0.ebuild,v 1.1 2013/09/23 20:00:32 radhermit Exp $
+
+EAPI=5
+
+inherit autotools java-pkg-opt-2 flag-o-matic eutils
+
+DESCRIPTION="Blu-ray playback libraries"
+HOMEPAGE="http://www.videolan.org/developers/libbluray.html"
+SRC_URI="http://ftp.videolan.org/pub/videolan/libbluray/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="aacs java static-libs +truetype utils +xml"
+
+COMMON_DEPEND="
+	xml? ( dev-libs/libxml2 )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	aacs? ( media-libs/libaacs )
+	java? (
+		truetype? ( media-libs/freetype:2 )
+		>=virtual/jre-1.6
+	)
+"
+DEPEND="
+	${COMMON_DEPEND}
+	java? (
+		truetype? ( media-libs/freetype:2 )
+		>=virtual/jdk-1.6
+		dev-java/ant-core
+	)
+	virtual/pkgconfig
+"
+
+DOCS=( ChangeLog README.txt )
+
+src_prepare() {
+	if use java ; then
+		export JDK_HOME="$(java-config -g JAVA_HOME)"
+
+		# don't install a duplicate jar file
+		sed -i '/^jar_DATA/d' src/Makefile.am || die
+
+		eautoreconf
+
+		java-pkg-opt-2_src_prepare
+	fi
+}
+
+src_configure() {
+	local myconf
+	if use java; then
+		export JAVACFLAGS="$(java-pkg_javac-args)"
+		append-cflags "$(java-pkg_get-jni-cflags)"
+		myconf="$(use_with truetype freetype)"
+	fi
+
+	econf \
+		--disable-optimizations \
+		$(use_enable utils examples) \
+		$(use_enable java bdjava) \
+		$(use_enable static-libs static) \
+		$(use_with xml libxml2) \
+		${myconf}
+}
+
+src_install() {
+	default
+
+	if use utils; then
+		cd src/examples/
+		dobin clpi_dump index_dump mobj_dump mpls_dump sound_dump
+		cd .libs/
+		dobin bd_info bdsplice hdmv_test libbluray_test list_titles
+		if use java; then
+			dobin bdj_test
+		fi
+	fi
+
+	if use java; then
+		java-pkg_dojar "${S}"/src/.libs/${PN}.jar
+		doenvd "${FILESDIR}"/90${PN}
+	fi
+
+	prune_libtool_files
+}
diff --git a/media-libs/libbluray/libbluray-9999.ebuild b/media-libs/libbluray/libbluray-9999.ebuild
index 28121eeb86df..75d3636d618b 100644
--- a/media-libs/libbluray/libbluray-9999.ebuild
+++ b/media-libs/libbluray/libbluray-9999.ebuild
@@ -1,10 +1,10 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/libbluray-9999.ebuild,v 1.12 2013/09/22 13:59:37 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/libbluray-9999.ebuild,v 1.13 2013/09/23 20:00:32 radhermit Exp $
 
-EAPI=4
+EAPI=5
 
-inherit autotools java-pkg-opt-2 git-2 flag-o-matic eutils
+inherit autotools java-pkg-opt-2 git-r3 flag-o-matic eutils
 
 EGIT_REPO_URI="git://git.videolan.org/libbluray.git"
 
@@ -14,7 +14,7 @@ HOMEPAGE="http://www.videolan.org/developers/libbluray.html"
 LICENSE="LGPL-2.1"
 SLOT="0"
 KEYWORDS=""
-IUSE="aacs java static-libs utils +xml"
+IUSE="aacs java static-libs +truetype utils +xml"
 
 COMMON_DEPEND="
 	xml? ( dev-libs/libxml2 )
@@ -22,11 +22,15 @@ COMMON_DEPEND="
 RDEPEND="
 	${COMMON_DEPEND}
 	aacs? ( media-libs/libaacs )
-	java? ( >=virtual/jre-1.6 )
+	java? (
+		truetype? ( media-libs/freetype:2 )
+		>=virtual/jre-1.6
+	)
 "
 DEPEND="
 	${COMMON_DEPEND}
 	java? (
+		truetype? ( media-libs/freetype:2 )
 		>=virtual/jdk-1.6
 		dev-java/ant-core
 	)
@@ -36,28 +40,31 @@ DEPEND="
 DOCS=( ChangeLog README.txt )
 
 src_prepare() {
-	use java && export JDK_HOME="$(java-config -g JAVA_HOME)"
-	eautoreconf
+	if use java ; then
+		export JDK_HOME="$(java-config -g JAVA_HOME)"
 
-	java-pkg-opt-2_src_prepare
+		# don't install a duplicate jar file
+		sed -i '/^jar_DATA/d' src/Makefile.am || die
+
+		java-pkg-opt-2_src_prepare
+	fi
+	eautoreconf
 }
 
 src_configure() {
-	local myconf=""
+	local myconf
 	if use java; then
 		export JAVACFLAGS="$(java-pkg_javac-args)"
 		append-cflags "$(java-pkg_get-jni-cflags)"
-		myconf="--with-jdk=${JDK_HOME}"
+		myconf="$(use_with truetype freetype)"
 	fi
 
-	use xml && myconf+=" --enable-libxml2"
-
 	econf \
-		--disable-debug \
 		--disable-optimizations \
+		$(use_enable utils examples) \
 		$(use_enable java bdjava) \
 		$(use_enable static-libs static) \
-		$(use_enable utils examples) \
+		$(use_with xml libxml2) \
 		${myconf}
 }
 
@@ -75,7 +82,7 @@ src_install() {
 	fi
 
 	if use java; then
-		java-pkg_dojar "${S}/src/.libs/${PN}.jar"
+		java-pkg_dojar "${S}"/src/.libs/${PN}.jar
 		doenvd "${FILESDIR}"/90${PN}
 	fi