version bump and add avx useflags, bug #493986

(Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

3 files changed, 133 insertions, 6 deletions

diff --git a/media-libs/libvpx/ChangeLog b/media-libs/libvpx/ChangeLog
index a80f9c74f8e9..2d781f3594c3 100644
--- a/media-libs/libvpx/ChangeLog
+++ b/media-libs/libvpx/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libvpx
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libvpx/ChangeLog,v 1.97 2013/10/01 04:49:26 vapier Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libvpx/ChangeLog,v 1.98 2014/01/14 20:50:25 aballier Exp $
+
+*libvpx-1.3.0 (14 Jan 2014)
+
+  14 Jan 2014; Alexis Ballier <aballier@gentoo.org> +libvpx-1.3.0.ebuild,
+  libvpx-9999.ebuild:
+  version bump and add avx useflags, bug #493986
 
   01 Oct 2013; Mike Frysinger <vapier@gentoo.org> libvpx-1.1.0.ebuild,
   libvpx-1.2.0_pre20130625.ebuild, libvpx-9999.ebuild:
diff --git a/media-libs/libvpx/libvpx-1.3.0.ebuild b/media-libs/libvpx/libvpx-1.3.0.ebuild
new file mode 100644
index 000000000000..c407180ddc09
--- /dev/null
+++ b/media-libs/libvpx/libvpx-1.3.0.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libvpx/libvpx-1.3.0.ebuild,v 1.1 2014/01/14 20:50:25 aballier Exp $
+
+EAPI=4
+inherit multilib toolchain-funcs multilib-minimal
+
+LIBVPX_TESTDATA_VER=1.3.0
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-2
+	EGIT_REPO_URI="https://chromium.googlesource.com/webm/${PN}.git"
+	KEYWORDS=""
+elif [[ ${PV} == *pre* ]]; then
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+else
+	SRC_URI="http://webm.googlecode.com/files/${PN}-v${PV}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${PN}-v${PV}"
+fi
+# generated by: make LIBVPX_TEST_DATA_PATH=libvpx-testdata testdata + tar'ing
+# it.
+SRC_URI="${SRC_URI}
+	test? ( mirror://gentoo/${PN}-testdata-${LIBVPX_TESTDATA_VER}.tar.bz2 )"
+
+DESCRIPTION="WebM VP8 Codec SDK"
+HOMEPAGE="http://www.webmproject.org"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="altivec avx avx2 doc mmx postproc sse sse2 sse3 ssse3 sse4_1 static-libs test +threads"
+
+RDEPEND="abi_x86_32? ( !app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
+DEPEND="abi_x86_32? ( dev-lang/yasm )
+	abi_x86_64? ( dev-lang/yasm )
+	x86-fbsd? ( dev-lang/yasm )
+	amd64-fbsd? ( dev-lang/yasm )
+	doc? (
+		app-doc/doxygen
+		dev-lang/php
+	)
+"
+
+REQUIRED_USE="
+	sse2? ( mmx )
+	ssse3? ( sse2 )
+	"
+
+multilib_src_configure() {
+	unset CODECS #357487
+
+	# let the build system decide which AS to use (it honours $AS but
+	# then feeds it with yasm flags without checking...) #345161
+	tc-export AS
+	case "${CHOST}" in
+		i?86*) export AS=yasm;;
+		x86_64*) export AS=yasm;;
+	esac
+
+	# http://bugs.gentoo.org/show_bug.cgi?id=384585
+	# https://bugs.gentoo.org/show_bug.cgi?id=465988
+	# copied from php-pear-r1.eclass
+	addpredict /usr/share/snmp/mibs/.index
+	addpredict /var/lib/net-snmp/
+	addpredict /var/lib/net-snmp/mib_indexes
+	addpredict /session_mm_cli0.sem
+
+	# Build with correct toolchain.
+	tc-export CC CXX AR NM
+	# Link with gcc by default, the build system should override this if needed.
+	export LD="${CC}"
+
+	local myconf
+	if [ "${ABI}" = "${DEFAULT_ABI}" ] ; then
+		myconf+=" $(use_enable doc install-docs) $(use_enable doc docs)"
+	else
+		# not needed for multilib and will be overwritten anyway.
+		myconf+=" --disable-examples --disable-install-docs --disable-docs"
+	fi
+
+	"${S}/configure" \
+		--prefix="${EPREFIX}"/usr \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--enable-pic \
+		--enable-vp8 \
+		--enable-shared \
+		--extra-cflags="${CFLAGS}" \
+		$(use_enable altivec) \
+		$(use_enable avx) \
+		$(use_enable avx2) \
+		$(use_enable mmx) \
+		$(use_enable postproc) \
+		$(use_enable sse) \
+		$(use_enable sse2) \
+		$(use_enable sse3) \
+		$(use_enable sse4_1) \
+		$(use_enable ssse3) \
+		$(use_enable static-libs static) \
+		$(use_enable test unit-tests) \
+		$(use_enable threads multithread) \
+		${myconf} \
+		|| die
+}
+
+multilib_src_compile() {
+	# build verbose by default and do not build examples that will not be installed
+	emake verbose=yes GEN_EXAMPLES=
+}
+
+multilib_src_test() {
+	LD_LIBRARY_PATH="${BUILD_DIR}:${LD_LIBRARY_PATH}" \
+		emake verbose=yes GEN_EXAMPLES=  LIBVPX_TEST_DATA_PATH="${WORKDIR}/${PN}-testdata" test
+}
+
+multilib_src_install() {
+	emake verbose=yes GEN_EXAMPLES= DESTDIR="${D}" install
+	[ "${ABI}" = "${DEFAULT_ABI}" ] && use doc && dohtml docs/html/*
+}
diff --git a/media-libs/libvpx/libvpx-9999.ebuild b/media-libs/libvpx/libvpx-9999.ebuild
index 1897243eaf1c..ea2701f9e0e0 100644
--- a/media-libs/libvpx/libvpx-9999.ebuild
+++ b/media-libs/libvpx/libvpx-9999.ebuild
@@ -1,11 +1,11 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libvpx/libvpx-9999.ebuild,v 1.45 2013/10/01 04:49:26 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libvpx/libvpx-9999.ebuild,v 1.46 2014/01/14 20:50:25 aballier Exp $
 
 EAPI=4
 inherit multilib toolchain-funcs multilib-minimal
 
-LIBVPX_TESTDATA_VER=1.2.0
+LIBVPX_TESTDATA_VER=1.3.0
 
 if [[ ${PV} == *9999* ]]; then
 	inherit git-2
@@ -29,7 +29,7 @@ HOMEPAGE="http://www.webmproject.org"
 
 LICENSE="BSD"
 SLOT="0"
-IUSE="altivec doc mmx postproc sse sse2 sse3 ssse3 sse4_1 static-libs test +threads"
+IUSE="altivec avx avx2 doc mmx postproc sse sse2 sse3 ssse3 sse4_1 static-libs test +threads"
 
 RDEPEND="abi_x86_32? ( !app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
 DEPEND="abi_x86_32? ( dev-lang/yasm )
@@ -87,6 +87,8 @@ multilib_src_configure() {
 		--enable-shared \
 		--extra-cflags="${CFLAGS}" \
 		$(use_enable altivec) \
+		$(use_enable avx) \
+		$(use_enable avx2) \
 		$(use_enable mmx) \
 		$(use_enable postproc) \
 		$(use_enable sse) \