Adapt to >=numpy-1.9.0 (bug #544504). Thanks Teun.

(Portage version: 2.2.19/cvs/Linux x86_64, signed Manifest commit with key 0x762053D5)

4 files changed, 129 insertions, 3 deletions

diff --git a/media-radio/wspr/ChangeLog b/media-radio/wspr/ChangeLog
index d253ac9c4659..5ed4377aea59 100644
--- a/media-radio/wspr/ChangeLog
+++ b/media-radio/wspr/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-radio/wspr
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-radio/wspr/ChangeLog,v 1.15 2015/04/08 18:14:38 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-radio/wspr/ChangeLog,v 1.16 2015/05/18 14:32:00 tomjbe Exp $
+
+*wspr-3.01-r1 (18 May 2015)
+
+  18 May 2015; Thomas Beierlein <tomjbe@gentoo.org> wspr-3.01.ebuild,
+  +wspr-3.01-r1.ebuild, +files/wspr-3.01-numpy.patch:
+  Adapt to >=numpy-1.9.0 (bug #544504). Thanks Teun.
 
   08 Apr 2015; Michał Górny <mgorny@gentoo.org> wspr-2.00-r2.ebuild,
   wspr-3.01.ebuild:
diff --git a/media-radio/wspr/files/wspr-3.01-numpy.patch b/media-radio/wspr/files/wspr-3.01-numpy.patch
new file mode 100644
index 000000000000..2c9174dff58a
--- /dev/null
+++ b/media-radio/wspr/files/wspr-3.01-numpy.patch
@@ -0,0 +1,23 @@
+# Numpy-1.9 dropped oldnumeric and numarray
+--- WsprMod/specjt.py.orig	2015-05-18 15:49:37.000000000 +0200
++++ WsprMod/specjt.py	2015-05-18 15:49:48.000000000 +0200
+@@ -12,7 +12,7 @@
+ import w
+ 
+ try:
+-    from numpy.oldnumeric import zeros, multiarray
++    from numpy import zeros, multiarray
+ except:
+     from Numeric import zeros, multiarray
+ import Image, ImageTk, ImageDraw
+--- wspr.py.orig	2015-05-18 15:47:13.000000000 +0200
++++ wspr.py	2015-05-18 15:47:38.000000000 +0200
+@@ -31,7 +31,7 @@
+ from WsprMod import palettes

+ from math import log10

+ try:

+-    from numpy.oldnumeric import zeros

++    from numpy import zeros

+ except: 

+     from Numeric import zeros

+ import array

diff --git a/media-radio/wspr/wspr-3.01-r1.ebuild b/media-radio/wspr/wspr-3.01-r1.ebuild
new file mode 100644
index 000000000000..732de0ce64a6
--- /dev/null
+++ b/media-radio/wspr/wspr-3.01-r1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-radio/wspr/wspr-3.01-r1.ebuild,v 1.1 2015/05/18 14:32:00 tomjbe Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="tk"
+
+inherit autotools fortran-2 distutils-r1 flag-o-matic multilib toolchain-funcs
+
+MY_P=${P}.r2792
+
+DESCRIPTION="Weak Signal Propagation Reporter"
+HOMEPAGE="http://www.physics.princeton.edu/pulsar/K1JT/wspr.html"
+SRC_URI="http://dev.gentoo.org/~tomjbe/distfiles/${MY_P}.tgz"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	virtual/python-imaging[tk,${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.9.0[${PYTHON_USEDEP}]
+	virtual/pmw[${PYTHON_USEDEP}]
+	sci-libs/fftw:3.0
+	media-libs/hamlib
+	media-libs/portaudio
+	media-libs/libsamplerate"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( BUGS WSPR_Announcement.TXT WSPR0_Instructions.TXT WSPR_Quick_Start.TXT )
+
+pkg_setup() {
+	fortran-2_pkg_setup
+}
+
+get_fcomp() {
+	case $(tc-getFC) in
+	*gfortran* )	FCOMP="gfortran" ;;
+	* ) 			FCOMP=$(tc-getFC) ;;
+	esac
+}
+
+python_prepare_all() {
+	tc-export FC
+	get_fcomp
+	export FC="${FCOMP}"
+
+	local PATCHES=(
+		"${FILESDIR}"/${PN}-2.00-libdir.patch
+		"${FILESDIR}"/${P}-verbose.patch
+		"${FILESDIR}"/${PN}-3.01-script.patch
+		"${FILESDIR}"/${P}-PIL.patch
+		# adapt to numpy-1.9 - bug #544504
+		"${FILESDIR}"/${P}-numpy.patch
+	)
+
+	distutils-r1_python_prepare_all
+
+	sed -i -e "s/LDFLAGS} ${LIBS}/LDFLAGS} -fPIC ${LIBS}/" Makefile.in || die
+	sed -i -e "s#/usr/local/lib#/usr/$(get_libdir)#" configure.ac || die
+	sed -i -e '/makedirs/d' setup.py || die
+	eautoreconf
+}
+
+# Note: very hacky build system.
+# autoconf which doesn't really need Python
+# then custom Makefile which compiles the Python module with f2py
+# and finally hacked setup.py which relies on w.so created by make
+
+src_configure() {
+	# configure the build of the fortran module
+	econf --with-portaudio-lib-dir=/usr/$(get_libdir)
+
+	# then fork the sources
+	python_copy_sources
+	DISTUTILS_IN_SOURCE_BUILD=1
+}
+
+python_compile() {
+	# -shared is neded by f2py but cannot be set earlier as configure does
+	# not like it
+	local LDFLAGS=${LDFLAGS}
+	append-ldflags -shared
+	emake -j1
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	dobin wspr
+	insinto /usr/share/${PN}
+	doins hamlib_rig_numbers
+}
diff --git a/media-radio/wspr/wspr-3.01.ebuild b/media-radio/wspr/wspr-3.01.ebuild
index 33dfe14a7117..a5b559be55e3 100644
--- a/media-radio/wspr/wspr-3.01.ebuild
+++ b/media-radio/wspr/wspr-3.01.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-radio/wspr/wspr-3.01.ebuild,v 1.2 2015/04/08 18:14:38 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-radio/wspr/wspr-3.01.ebuild,v 1.3 2015/05/18 14:32:00 tomjbe Exp $
 
 EAPI="5"
 PYTHON_COMPAT=( python2_7 )
@@ -21,7 +21,7 @@ IUSE=""
 
 RDEPEND="
 	virtual/python-imaging[tk,${PYTHON_USEDEP}]
-	dev-python/numpy[${PYTHON_USEDEP}]
+	<dev-python/numpy-1.9.0[${PYTHON_USEDEP}]
 	virtual/pmw[${PYTHON_USEDEP}]
 	sci-libs/fftw:3.0
 	media-libs/hamlib