This release works around the GCC 4.1 issues, which were most noticable on AMD64 systems. Bugfixes only, new features will be in the 1.2 branch.

(Portage version: 2.1.1_pre5-r3)

3 files changed, 121 insertions, 1 deletions

diff --git a/media-sound/audacious/ChangeLog b/media-sound/audacious/ChangeLog
index 29b70de341f9..6e53df57d7a7 100644
--- a/media-sound/audacious/ChangeLog
+++ b/media-sound/audacious/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/audacious
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v 1.62 2006/08/09 08:57:11 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v 1.63 2006/08/25 14:37:32 chainsaw Exp $
+
+*audacious-1.1.2 (25 Aug 2006)
+
+  25 Aug 2006; Tony Vroon <chainsaw@gentoo.org> +audacious-1.1.2.ebuild:
+  This release works around the GCC 4.1 issues, which were most noticable on
+  AMD64 systems. Bugfixes only, new features will be in the 1.2 branch.
 
   09 Aug 2006; Tony Vroon <chainsaw@gentoo.org> audacious-1.1.1-r1.ebuild:
   Make taglib dependency unconditional, closes bug #143302.
diff --git a/media-sound/audacious/audacious-1.1.2.ebuild b/media-sound/audacious/audacious-1.1.2.ebuild
new file mode 100644
index 000000000000..524ef86a2d78
--- /dev/null
+++ b/media-sound/audacious/audacious-1.1.2.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/audacious-1.1.2.ebuild,v 1.1 2006/08/25 14:37:32 chainsaw Exp $
+
+inherit flag-o-matic
+
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="http://audacious-media-player.org/"
+SRC_URI="http://audacious-media-player.org/release/${P}.tgz
+	mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="aac alsa arts chardet esd flac gnome jack lirc mmx modplug mp3 musepack nls oss sid sndfile timidity vorbis wma"
+
+RDEPEND="app-arch/unzip
+	net-misc/curl
+	media-libs/musicbrainz
+	>=x11-libs/gtk+-2.6
+	>=gnome-base/libglade-2.3.1
+	>=dev-cpp/libbinio-1.4
+	media-libs/taglib
+	alsa? ( >=media-libs/alsa-lib-1.0.9_rc2 )
+	arts? ( kde-base/arts )
+	esd? ( >=media-sound/esound-0.2.30 )
+	flac? ( >=media-libs/libvorbis-1.0
+		>=media-libs/flac-1.1.2 )
+	gnome? ( >=gnome-base/gconf-2.6.0 )
+	jack? ( >=media-libs/bio2jack-0.4
+		media-libs/libsamplerate
+		media-sound/jack-audio-connection-kit )
+	lirc? ( app-misc/lirc )
+	modplug? ( media-libs/libmodplug )
+	musepack? ( media-libs/libmpcdec )
+	sid? ( media-libs/libsidplay )
+	sndfile? ( media-libs/libsndfile )
+	timidity? ( media-sound/timidity++ )
+	vorbis? ( >=media-libs/libvorbis-1.0
+		  >=media-libs/libogg-1.0 )"
+DEPEND="${RDEPEND}
+	nls? ( dev-util/intltool )
+	>=dev-util/pkgconfig-0.9.0"
+
+mp3_warning() {
+	if ! useq mp3 ; then
+		echo
+		ewarn "MP3 support is now optional, you may want to enable the mp3 USE-flag"
+		echo
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+	epatch ${FILESDIR}/1.1.1-ffwma-asm.diff
+}
+
+src_compile() {
+	mp3_warning
+
+	# Bug #42893
+	replace-flags "-Os" "-O2"
+	# Bug #86689
+	is-flag "-O*" || append-flags -O
+
+	econf \
+		--with-dev-dsp=/dev/sound/dsp \
+		--with-dev-mixer=/dev/sound/mixer \
+		$(use_enable mmx simd) \
+		$(use_enable gnome gconf) \
+		$(use_enable vorbis) \
+		$(use_enable esd) \
+		$(use_enable mp3) \
+		$(use_enable nls) \
+		$(use_enable oss) \
+		$(use_enable alsa) \
+		$(use_enable arts) \
+		$(use_enable flac) \
+		$(use_enable aac) \
+		$(use_enable modplug) \
+		$(use_enable lirc) \
+		$(use_enable sndfile) \
+		$(use_enable wma) \
+		$(use_enable sid) \
+		$(use_enable musepack) \
+		$(use_enable jack) \
+		$(use_enable timidity) \
+		$(use_enable chardet) \
+		|| die
+
+	emake || die "make failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die
+	dodoc AUTHORS NEWS README
+
+	# Gentoo_ice skin installation; bug #109772
+	insinto /usr/share/audacious/Skins/gentoo_ice
+	doins "${WORKDIR}"/gentoo_ice/*
+	docinto gentoo_ice
+	dodoc "${WORKDIR}"/README
+}
+
+pkg_postinst() {
+	mp3_warning
+}
diff --git a/media-sound/audacious/files/digest-audacious-1.1.2 b/media-sound/audacious/files/digest-audacious-1.1.2
new file mode 100644
index 000000000000..f5a998a9027a
--- /dev/null
+++ b/media-sound/audacious/files/digest-audacious-1.1.2
@@ -0,0 +1,6 @@
+MD5 14aba1f9c42a48afeeb6ce5dcaf180c6 audacious-1.1.2.tgz 3394364
+RMD160 920cb247dc1e583364cfac9cc8f1f0c39c37550e audacious-1.1.2.tgz 3394364
+SHA256 54f8f9e10e9a20a0a77e9d063708cd4bd572576ea9b36b9b1bb3ea3cbeaa1a81 audacious-1.1.2.tgz 3394364
+MD5 41eababfa8bad11e9e34e467cdfb86be gentoo_ice-xmms-0.2.tar.bz2 51839
+RMD160 11439cbebf8c6dc5745c8593a79e88303d094544 gentoo_ice-xmms-0.2.tar.bz2 51839
+SHA256 d1be63368b76f4a8b1d5b0e955cd7a77177f56a7f0b828c6603d8fd2836422b1 gentoo_ice-xmms-0.2.tar.bz2 51839