Version bump. Add sbsms use flag.

(Portage version: 2.2.0_alpha114/cvs/Linux x86_64)

3 files changed, 112 insertions, 2 deletions

diff --git a/media-sound/audacity/ChangeLog b/media-sound/audacity/ChangeLog
index 17372a16ec63..a2633ced02ce 100644
--- a/media-sound/audacity/ChangeLog
+++ b/media-sound/audacity/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/audacity
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/audacity/ChangeLog,v 1.175 2012/06/03 14:01:04 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacity/ChangeLog,v 1.176 2012/06/30 04:07:44 radhermit Exp $
+
+*audacity-2.0.1 (30 Jun 2012)
+
+  30 Jun 2012; Tim Harder <radhermit@gentoo.org> +audacity-2.0.1.ebuild,
+  metadata.xml:
+  Version bump. Add sbsms use flag.
 
   03 Jun 2012; Anthony G. Basile <blueness@gentoo.org> audacity-2.0.0.ebuild:
   Keyword ~mips
diff --git a/media-sound/audacity/audacity-2.0.1.ebuild b/media-sound/audacity/audacity-2.0.1.ebuild
new file mode 100644
index 000000000000..528208a362cb
--- /dev/null
+++ b/media-sound/audacity/audacity-2.0.1.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacity/audacity-2.0.1.ebuild,v 1.1 2012/06/30 04:07:44 radhermit Exp $
+
+EAPI=4
+
+inherit eutils wxwidgets autotools versionator
+
+MY_PV=$(replace_version_separator 3 -)
+MY_P="${PN}-src-${MY_PV}"
+MY_T="${PN}-minsrc-${MY_PV}"
+DESCRIPTION="Free crossplatform audio editor"
+HOMEPAGE="http://audacity.sourceforge.net/"
+SRC_URI="http://${PN}.googlecode.com/files/${MY_T}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa ffmpeg flac id3tag jack ladspa libsamplerate midi mp3 sbsms soundtouch twolame vamp vorbis"
+RESTRICT="test"
+
+COMMON_DEPEND="x11-libs/wxGTK:2.8[X]
+	>=app-arch/zip-2.3
+	>=media-libs/libsndfile-1.0.0
+	dev-libs/expat
+	libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )
+	vorbis? ( >=media-libs/libvorbis-1.0 )
+	mp3? ( >=media-libs/libmad-0.14.2b )
+	flac? ( >=media-libs/flac-1.2.0[cxx] )
+	id3tag? ( media-libs/libid3tag )
+	sbsms? ( media-libs/libsbsms )
+	soundtouch? ( >=media-libs/libsoundtouch-1.3.1 )
+	vamp? ( >=media-libs/vamp-plugin-sdk-2.0 )
+	twolame? ( media-sound/twolame )
+	ffmpeg? ( virtual/ffmpeg )
+	alsa? ( media-libs/alsa-lib )
+	jack? ( >=media-sound/jack-audio-connection-kit-0.103.0 )"
+# Crashes at  startup here...
+#	lv2? ( >=media-libs/slv2-0.6.0 )
+# Disabled upstream ATM
+#  ladspa? ( >=media-libs/liblrdf-0.4.0 )
+
+RDEPEND="${COMMON_DEPEND}
+	mp3? ( >=media-sound/lame-3.70 )"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig"
+
+REQUIRED_USE="soundtouch? ( midi )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.3.13-automagic.patch
+	epatch "${FILESDIR}"/${PN}-1.3.14-typecast.patch
+
+	if ! use ffmpeg ; then
+		sed -i -e "s:^#define EXPERIMENTAL_OD_FFMPEG://\0:" src/Experimental.h || die
+	fi
+
+	AT_M4DIR="${S}/m4" eautoreconf
+}
+
+src_configure() {
+	WX_GTK_VER="2.8"
+	need-wxwidgets unicode
+
+	# * always use system libraries if possible
+	# * options listed in the order that configure --help lists them
+	# * if libsamplerate not requested, use libresample instead.
+	econf \
+		--enable-unicode \
+		--enable-nyquist \
+		$(use_enable ladspa) \
+		--with-libsndfile=system \
+		--with-expat=system \
+		$(use_with libsamplerate) \
+		$(use_with !libsamplerate libresample) \
+		$(use_with vorbis libvorbis) \
+		$(use_with mp3 libmad) \
+		$(use_with flac libflac) \
+		$(use_with id3tag libid3tag) \
+		$(use_with sbsms) \
+		$(use_with soundtouch) \
+		$(use_with vamp libvamp) \
+		$(use_with twolame libtwolame) \
+		$(use_with ffmpeg) \
+		$(use_with midi) \
+		$(use_with alsa) \
+		$(use_with jack)
+}
+
+# $(use_with lv2 slv2) \
+# $(use_with ladspa liblrdf) \
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	# Remove bad doc install
+	rm -rf "${D}"/usr/share/doc
+
+	# Install our docs
+	dodoc README.txt
+}
diff --git a/media-sound/audacity/metadata.xml b/media-sound/audacity/metadata.xml
index aa98ae894815..37d4cc857b6a 100644
--- a/media-sound/audacity/metadata.xml
+++ b/media-sound/audacity/metadata.xml
@@ -10,7 +10,8 @@
 	<use>
 		<flag name="id3tag">Enables ID3 tagging with id3tag library</flag>
 		<flag name="midi">Enables MIDI support</flag>
-		<flag name="soundtouch">Enables soundtouch library support</flag>
+		<flag name="sbsms">Enables sbsms library support for pitch and tempo changing</flag>
+		<flag name="soundtouch">Enables soundtouch library support for pitch and tempo changing</flag>
 		<flag name="twolame">Enables twolame support (MPEG Audio Layer 2 encoder)</flag>
 		<flag name="vamp">Enables vamp plugins support (Audio analysing plugins)</flag>
 	</use>