Add banshee-1.5.0 masked. Take maintainership.

(Portage version: 2.2_rc33/cvs/Linux x86_64)

3 files changed, 143 insertions, 2 deletions

diff --git a/media-sound/banshee/ChangeLog b/media-sound/banshee/ChangeLog
index 6b3ee2cf6e21..9fdeb0406b49 100644
--- a/media-sound/banshee/ChangeLog
+++ b/media-sound/banshee/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/banshee
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/banshee/ChangeLog,v 1.94 2009/05/27 21:00:51 loki_val Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/banshee/ChangeLog,v 1.95 2009/06/01 19:54:06 loki_val Exp $
+
+*banshee-1.5.0 (01 Jun 2009)
+
+  01 Jun 2009; Peter Alfredsen <loki_val@gentoo.org> +banshee-1.5.0.ebuild,
+  metadata.xml:
+  Add banshee-1.5.0 masked. Take maintainership.
 
   26 May 2009; Peter Alfredsen <loki_val@gentoo.org> banshee-1.4.3.ebuild,
   banshee-1.4.3-r1.ebuild:
diff --git a/media-sound/banshee/banshee-1.5.0.ebuild b/media-sound/banshee/banshee-1.5.0.ebuild
new file mode 100644
index 000000000000..d7dd4000be4a
--- /dev/null
+++ b/media-sound/banshee/banshee-1.5.0.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/banshee/banshee-1.5.0.ebuild,v 1.1 2009/06/01 19:54:06 loki_val Exp $
+
+EAPI=2
+
+inherit eutils mono gnome2-utils fdo-mime versionator
+
+GVER=0.10.7
+
+DESCRIPTION="Import, organize, play, and share your music using a simple and powerful interface."
+HOMEPAGE="http://banshee-project.org"
+
+BANSHEE_V2=$(get_version_component_range 2)
+[[ $((${BANSHEE_V2} % 2)) -eq 0 ]] && RELTYPE=stable || RELTYPE=unstable
+SRC_URI="http://download.banshee-project.org/${PN}/${RELTYPE}/${PV}/${PN}-1-${PV}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="+aac boo daap doc +encode +flac ipod karma +mad mtp podcast test +vorbis"
+
+RDEPEND=">=dev-lang/mono-2
+	gnome-base/gnome-settings-daemon
+	x11-themes/gnome-icon-theme
+	sys-apps/dbus
+	>=dev-dotnet/gtk-sharp-2.12
+	>=dev-dotnet/gconf-sharp-2.24.0
+	>=dev-dotnet/gnome-sharp-2.24.0
+	>=dev-dotnet/notify-sharp-0.4.0_pre20080912-r1
+	>=media-libs/gstreamer-0.10.21-r3
+	>=media-libs/gst-plugins-bad-${GVER}
+	>=media-libs/gst-plugins-good-${GVER}
+	>=media-libs/gst-plugins-ugly-${GVER}
+	>=media-plugins/gst-plugins-alsa-${GVER}
+	>=media-plugins/gst-plugins-gnomevfs-${GVER}
+	>=media-plugins/gst-plugins-gconf-${GVER}
+	|| (
+		>=media-plugins/gst-plugins-cdparanoia-${GVER}
+		>=media-plugins/gst-plugins-cdio-${GVER}
+	)
+	media-libs/musicbrainz:1
+	>=dev-dotnet/dbus-glib-sharp-0.4.1
+	>=dev-dotnet/dbus-sharp-0.6.1a
+	>=dev-dotnet/mono-addins-0.4[gtk]
+	>=dev-dotnet/taglib-sharp-2.0.3.1
+	>=dev-db/sqlite-3.4
+	aac? (
+		>=media-plugins/gst-plugins-faad-${GVER}
+	)
+	boo? (
+		>=dev-lang/boo-0.8.1
+	)
+	daap? (
+	 	>=dev-dotnet/mono-zeroconf-0.8.0-r1
+	)
+	doc? (
+		virtual/monodoc
+	)
+	encode? (
+		>=media-plugins/gst-plugins-lame-${GVER}
+		>=media-plugins/gst-plugins-taglib-${GVER}
+	)
+	flac? (
+		>=media-plugins/gst-plugins-flac-${GVER}
+	)
+	ipod? (
+		>=dev-dotnet/ipod-sharp-0.8.1
+	)
+	mad? (
+		>=media-plugins/gst-plugins-mad-${GVER}
+	)
+	mtp? (
+		media-libs/libmtp
+	)
+	vorbis? (
+		>=media-plugins/gst-plugins-ogg-${GVER}
+		>=media-plugins/gst-plugins-vorbis-${GVER}
+	)"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+DOCS="AUTHORS ChangeLog HACKING NEWS README"
+
+S=${WORKDIR}/${PN}-1-${PV}
+
+src_configure() {
+	local myconf="--disable-dependency-tracking --disable-static
+		--enable-gnome --enable-schemas-install
+		--with-gconf-schema-file-dir=/etc/gconf/schemas
+		--with-vendor-build-id=Gentoo/${PN}/${PVR}
+		--disable-torrent
+		--disable-shave"
+
+	econf \
+		$(use_enable doc docs) \
+		$(use_enable boo) \
+		$(use_enable mtp) \
+		$(use_enable daap) \
+		$(use_enable ipod) \
+		$(use_enable podcast) \
+		$(use_enable karma) \
+		${myconf}
+}
+
+src_compile() {
+	emake MCS=/usr/bin/gmcs
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install efailed"
+	find "${D}" -name '*.la' -delete
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
diff --git a/media-sound/banshee/metadata.xml b/media-sound/banshee/metadata.xml
index 747d2aafa32f..80999be39ab5 100644
--- a/media-sound/banshee/metadata.xml
+++ b/media-sound/banshee/metadata.xml
@@ -1,12 +1,17 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
+  <maintainer>
+    <email>loki_val@gentoo.org</email>
+    <name>Peter Alfredsen</name>
+  </maintainer>
+  <herd>dotnet</herd>
   <herd>sound</herd>
   <use>
     <flag name="boo">Use external Boo instead of the bundled one</flag>
     <flag name="daap">Build with Daap support</flag>
     <flag name="mtp">Build with Media Transfer Protocol support</flag>
-	<flag name="karma">Build with karma support</flag>
+    <flag name="karma">Build with karma support</flag>
     <flag name="podcast">Build with podcasting support</flag>
   </use>
 </pkgmetadata>