Version bump

(Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key 84F20B43)

3 files changed, 238 insertions, 3 deletions

diff --git a/media-sound/mpd/ChangeLog b/media-sound/mpd/ChangeLog
index b8f95a505a84..f98525282699 100644
--- a/media-sound/mpd/ChangeLog
+++ b/media-sound/mpd/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/mpd
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.356 2014/09/26 17:12:42 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.357 2014/10/19 08:56:15 angelos Exp $
+
+*mpd-0.19.1 (19 Oct 2014)
+
+  19 Oct 2014; Christoph Mende <angelos@gentoo.org> +mpd-0.19.1.ebuild,
+  metadata.xml:
+  Version bump
 
 *mpd-0.18.16 (26 Sep 2014)
 
diff --git a/media-sound/mpd/metadata.xml b/media-sound/mpd/metadata.xml
index bfc820b3b964..d757fb1bcbfc 100644
--- a/media-sound/mpd/metadata.xml
+++ b/media-sound/mpd/metadata.xml
@@ -16,14 +16,19 @@
 	<flag name="curl">Support for web stream listening</flag>
 	<flag name="faad">Use external faad library for AAC decoding</flag>
 	<flag name="fifo">Support writing audio to a FIFO</flag>
-	<flag name="fluidsynth">Enables Fluidsynth MIDI software synthesis</flag>
+	<flag name="fluidsynth">Enables Fluidsynth MIDI software synthesis (discouraged)</flag>
+	<flag name="glib">Enable GLib usage</flag>
 	<flag name="gme">Enables support for <pkg>media-libs/game-music-emu</pkg> for playing various video game music formats.</flag>
 	<flag name="id3tag">Support for ID3 tags</flag>
 	<flag name="inotify">Use the Linux kernel inotify subsystem to notice changes to mpd music library</flag>
 	<flag name="lame">Support for MP3 streaming via Icecast2</flag>
 	<flag name="lastfmradio">Support listening to last.fm radio stations</flag>
 	<flag name="libmpdclient">Enable support for remote mpd databases</flag>
+	<flag name="libsoxr">Enable the libsoxr resampler</flag>
+	<flag name="mp4v2">Enable the MP4v2 decoder</flag>
+	<flag name="mpg123">Enable support for mp3 decoding over media-sound/mpg123</flag>
 	<flag name="network">Enables network streaming support</flag>
+	<flag name="nfs">Enable support for the Network File System</flag>
 	<flag name="opus">Enable Opus codec support</flag>
 	<flag name="pipe">Support writing audio to a pipe</flag>
 	<flag name="recorder">Enables output plugin for recording radio streams</flag>
@@ -34,6 +39,5 @@
 	<flag name="twolame">Support twolame MPEG-2 encoding</flag>
 	<flag name="wildmidi">Enable MIDI support via wildmidi</flag>
 	<flag name="zip">Support for ZIP files</flag>
-    <flag name="mpg123">Enable support for mp3 decoding over media-sound/mpg123</flag>
   </use>
 </pkgmetadata>
diff --git a/media-sound/mpd/mpd-0.19.1.ebuild b/media-sound/mpd/mpd-0.19.1.ebuild
new file mode 100644
index 000000000000..b2d9f9180853
--- /dev/null
+++ b/media-sound/mpd/mpd-0.19.1.ebuild
@@ -0,0 +1,225 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-0.19.1.ebuild,v 1.1 2014/10/19 08:56:15 angelos Exp $
+
+EAPI=5
+inherit eutils flag-o-matic linux-info multilib readme.gentoo systemd user
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="http://www.musicpd.org"
+SRC_URI="http://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~sh ~x86 ~x86-fbsd ~x64-macos"
+IUSE="adplug +alsa ao audiofile bzip2 cdio +curl debug expat faad +fifo +ffmpeg
+	flac fluidsynth +glib gme +icu +id3tag +inotify +ipv6 jack lame mms
+	libmpdclient libsamplerate libsoxr +mad mikmod modplug mp4v2 mpg123 musepack
+	+network nfs ogg openal opus oss pipe pulseaudio recorder samba selinux sid
+	sndfile soundcloud sqlite systemd tcpd twolame unicode upnp vorbis wavpack
+	wildmidi zeroconf zip"
+
+OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pulseaudio recorder"
+DECODER_PLUGINS="adplug audiofile faad ffmpeg flac fluidsynth mad mikmod
+	modplug mpg123 musepack ogg flac sid vorbis wavpack wildmidi"
+ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
+
+REQUIRED_USE="|| ( ${OUTPUT_PLUGINS} )
+	|| ( ${DECODER_PLUGINS} )
+	mp4v2? ( faad )
+	network? ( || ( ${ENCODER_PLUGINS} ) )
+	recorder? ( || ( ${ENCODER_PLUGINS} ) )
+	opus? ( ogg )"
+
+RDEPEND="!<sys-cluster/mpich2-1.4_rc2
+	dev-libs/glib:2
+	adplug? ( media-libs/adplug )
+	alsa? ( media-sound/alsa-utils
+		media-libs/alsa-lib )
+	ao? ( media-libs/libao[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio-paranoia )
+	curl? ( net-misc/curl )
+	expat? ( dev-libs/expat )
+	faad? ( media-libs/faad2 )
+	ffmpeg? ( virtual/ffmpeg )
+	flac? ( media-libs/flac[ogg?] )
+	fluidsynth? ( media-sound/fluidsynth )
+	glib? ( dev-libs/glib:2 )
+	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
+	icu? ( dev-libs/icu:= )
+	id3tag? ( media-libs/libid3tag )
+	jack? ( media-sound/jack-audio-connection-kit )
+	lame? ( network? ( media-sound/lame ) )
+	libmpdclient? ( media-libs/libmpdclient )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod:0 )
+	mms? ( media-libs/libmms )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( >=media-sound/mpg123-1.12.2 )
+	mp4v2? ( media-libs/libmp4v2 )
+	musepack? ( media-sound/musepack-tools )
+	network? ( >=media-libs/libshout-2
+		!lame? ( !vorbis? ( media-libs/libvorbis ) ) )
+	nfs? ( net-fs/libnfs )
+	ogg? ( media-libs/libogg )
+	openal? ( media-libs/openal )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-sound/pulseaudio )
+	samba? ( net-fs/samba[smbclient] )
+	selinux? ( sec-policy/selinux-mpd )
+	sid? ( media-libs/libsidplay:2 )
+	sndfile? ( media-libs/libsndfile )
+	soundcloud? ( >=dev-libs/yajl-2 )
+	libsoxr? ( media-libs/soxr )
+	sqlite? ( dev-db/sqlite:3 )
+	systemd? ( sys-apps/systemd )
+	tcpd? ( sys-apps/tcp-wrappers )
+	twolame? ( media-sound/twolame )
+	upnp? ( net-libs/libupnp )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+pkg_setup() {
+	use network || ewarn "Icecast and Shoutcast streaming needs networking."
+	use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
+
+	enewuser mpd "" "" "/var/lib/mpd" audio
+
+	if use inotify; then
+		CONFIG_CHECK="~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	DOC_CONTENTS="If you will be starting mpd via /etc/init.d/mpd, please make
+		sure that MPD's pid_file is _set_."
+
+	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
+	epatch "${FILESDIR}"/${PN}-0.18.conf.patch
+}
+
+src_configure() {
+	local mpdconf="--enable-database --disable-roar --disable-documentation
+		--enable-dsd --enable-largefile --disable-despotify --disable-osx
+		--disable-shine-encoder --disable-solaris-output --enable-tcp
+		--enable-un --disable-werror
+		--docdir=${EPREFIX}/usr/share/doc/${PF}"
+
+	if use network; then
+		mpdconf+=" --enable-shout $(use_enable vorbis vorbis-encoder)
+			--enable-httpd-output $(use_enable lame lame-encoder)
+			$(use_enable twolame twolame-encoder)
+			$(use_enable audiofile wave-encoder)"
+	else
+		mpdconf+=" --disable-shout --disable-vorbis-encoder
+			--disable-httpd-output --disable-lame-encoder
+			--disable-twolame-encoder --disable-wave-encoder"
+	fi
+
+	if use samba || use upnp; then
+		mpdconf+=" --enable-neighbor-plugins"
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
+
+	econf \
+		$(use_enable libmpdclient)	\
+		$(use_enable expat)			\
+		$(use_enable upnp)			\
+		$(use_enable adplug)		\
+		$(use_enable alsa)			\
+		$(use_enable ao)			\
+		$(use_enable audiofile)		\
+		$(use_enable bzip2)			\
+		$(use_enable cdio cdio-paranoia) \
+		$(use_enable cdio iso9660)	\
+		$(use_enable curl)			\
+		$(use_enable samba smbclient) \
+		$(use_enable nfs)			\
+		$(use_enable debug)			\
+		$(use_enable ffmpeg)		\
+		$(use_enable fifo)			\
+		$(use_enable flac)			\
+		$(use_enable fluidsynth)	\
+		$(use_enable gme)			\
+		$(use_enable id3tag id3)	\
+		$(use_enable inotify)		\
+		$(use_enable ipv6)			\
+		$(use_enable jack)			\
+		$(use_enable soundcloud)	\
+		$(use_enable tcpd libwrap)	\
+		$(use_enable libsamplerate lsr) \
+		$(use_enable libsoxr soxr)	\
+		$(use_enable mad)			\
+		$(use_enable mikmod)		\
+		$(use_enable mms)			\
+		$(use_enable modplug)		\
+		$(use_enable mp4v2)			\
+		$(use_enable musepack mpc)	\
+		$(use_enable mpg123)		\
+		$(use_enable openal)		\
+		$(use_enable opus)			\
+		$(use_enable oss)			\
+		$(use_enable pipe pipe-output) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable recorder recorder-output) \
+		$(use_enable sid sidplay)	\
+		$(use_enable sndfile sndfile) \
+		$(use_enable sqlite)		\
+		$(use_enable systemd systemd-daemon) \
+		$(use_enable vorbis)		\
+		$(use_enable wavpack)		\
+		$(use_enable wildmidi)		\
+		$(use_enable zip zzip)		\
+		$(use_enable icu)			\
+		$(use_enable glib)			\
+		$(use_enable faad aac)		\
+		$(use_with zeroconf zeroconf avahi) \
+		"$(systemd_with_unitdir)"	\
+		${mpdconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	insinto /etc
+	newins doc/mpdconf.dist mpd.conf
+
+	newinitd "${FILESDIR}"/${PN}2.init ${PN}
+
+	if use unicode; then
+		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+			"${ED}"/etc/mpd.conf || die "sed failed"
+	fi
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotate ${PN}
+
+	use prefix || diropts -m0755 -o mpd -g audio
+	dodir /var/lib/mpd
+	keepdir /var/lib/mpd
+	dodir /var/lib/mpd/music
+	keepdir /var/lib/mpd/music
+	dodir /var/lib/mpd/playlists
+	keepdir /var/lib/mpd/playlists
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	# also change the homedir if the user has existed before
+	usermod -d "/var/lib/mpd" mpd
+}