Version bump to 0.3.2 version, and use eqmake4 to make sure the correct compiler is used.

(Portage version: 2.1.4)

1 files changed, 52 insertions, 0 deletions

diff --git a/media-sound/qjackctl/qjackctl-0.3.2.ebuild b/media-sound/qjackctl/qjackctl-0.3.2.ebuild
new file mode 100644
index 000000000000..d4d2dc2bf3d5
--- /dev/null
+++ b/media-sound/qjackctl/qjackctl-0.3.2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qjackctl/qjackctl-0.3.2.ebuild,v 1.1 2008/01/21 13:59:39 flameeyes Exp $
+
+inherit eutils qt4
+
+DESCRIPTION="A Qt application to control the JACK Audio Connection Kit and ALSA sequencer connections."
+HOMEPAGE="http://qjackctl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qjackctl/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+IUSE="alsa debug"
+
+DEPEND="alsa? ( media-libs/alsa-lib )
+	$(qt4_min_version 4.1)
+	media-sound/jack-audio-connection-kit"
+
+pkg_setup() {
+	if use alsa && ! built_with_use --missing true media-libs/alsa-lib midi; then
+		eerror ""
+		eerror "To be able to build ${CATEGORY}/${PN} with ALSA support you"
+		eerror "need to have built media-libs/alsa-lib with midi USE flag."
+		die "Missing midi USE flag on media-libs/alsa-lib"
+	fi
+}
+
+src_compile() {
+	econf \
+		$(use_enable alsa alsa-seq) \
+		$(use_enable debug) \
+		|| die "econf failed"
+
+	# Emulate what the Makefile does, so that we can get the correct
+	# compiler used.
+	eqmake4 ${PN}.pro -o ${PN}.mak || die "eqmake4 failed"
+
+	emake -f ${PN}.mak || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+
+	rm "${D}/usr/share/applications/qjackctl.desktop"
+
+	# Upstream desktop file is invalid, better stick with our for now.
+	make_desktop_entry "${PN}" "QjackCtl" "${PN}"
+
+	dodoc README ChangeLog TODO AUTHORS
+}