Version bump

(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

2 files changed, 82 insertions, 1 deletions

diff --git a/media-video/gnome-mplayer/ChangeLog b/media-video/gnome-mplayer/ChangeLog
index 3cb1249650a3..be99e421a095 100644
--- a/media-video/gnome-mplayer/ChangeLog
+++ b/media-video/gnome-mplayer/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/gnome-mplayer
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v 1.78 2012/06/17 05:52:24 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v 1.79 2012/11/24 16:31:28 ssuominen Exp $
+
+*gnome-mplayer-1.0.7 (24 Nov 2012)
+
+  24 Nov 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +gnome-mplayer-1.0.7.ebuild:
+  Version bump wrt #440978 by Alessandro Capogna
 
   17 Jun 2012; Ben de Groot <yngwin@gentoo.org> gnome-mplayer-1.0.5.ebuild,
   gnome-mplayer-1.0.6.ebuild:
diff --git a/media-video/gnome-mplayer/gnome-mplayer-1.0.7.ebuild b/media-video/gnome-mplayer/gnome-mplayer-1.0.7.ebuild
new file mode 100644
index 000000000000..76cfaf1bf625
--- /dev/null
+++ b/media-video/gnome-mplayer/gnome-mplayer-1.0.7.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/gnome-mplayer-1.0.7.ebuild,v 1.1 2012/11/24 16:31:28 ssuominen Exp $
+
+EAPI=5
+inherit fdo-mime gnome2-utils
+
+DESCRIPTION="A GTK+ interface to MPlayer"
+HOMEPAGE="http://code.google.com/p/gnome-mplayer/"
+SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="alsa +dbus +dconf gnome ipod libnotify musicbrainz pulseaudio"
+
+COMMON_DEPEND=">=dev-libs/glib-2.30
+	>=media-libs/gmtk-${PV}[dconf=]
+	>=x11-libs/gtk+-3.2:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	alsa? ( media-libs/alsa-lib )
+	dbus? ( >=dev-libs/dbus-glib-0.100 )
+	gnome? ( gnome-base/nautilus )
+	ipod? ( >=media-libs/libgpod-0.7 )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	musicbrainz? (
+		media-libs/musicbrainz:3
+		net-misc/curl
+		)
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.14 )"
+RDEPEND="${COMMON_DEPEND}
+	|| ( >=media-video/mplayer-1.0_rc4_p20100101[libass] media-video/mplayer2[libass] )"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+DOCS="ChangeLog README DOCS/*.txt DOCS/tech/*.txt"
+
+src_configure() {
+	econf \
+		--enable-gtk3 \
+		$(use_enable gnome nautilus) \
+		--with-gio \
+		$(use_with dbus) \
+		$(use_with alsa) \
+		$(use_with pulseaudio) \
+		$(use_with libnotify) \
+		$(use_with ipod libgpod) \
+		$(use_with musicbrainz libmusicbrainz3)
+}
+
+src_install() {
+	default
+	rm -rf "${ED}"/usr/share/doc/${PN}
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}