Version bump, update HOMEPAGE.

(Portage version: 2.2.0_alpha186/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 76 insertions, 1 deletions

diff --git a/media-video/mediainfo/ChangeLog b/media-video/mediainfo/ChangeLog
index d4c76ab39ca5..b741e17be704 100644
--- a/media-video/mediainfo/ChangeLog
+++ b/media-video/mediainfo/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/mediainfo
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v 1.66 2013/06/01 02:00:57 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v 1.67 2013/07/07 21:02:05 radhermit Exp $
+
+*mediainfo-0.7.64 (07 Jul 2013)
+
+  07 Jul 2013; Tim Harder <radhermit@gentoo.org> +mediainfo-0.7.64.ebuild:
+  Version bump, update HOMEPAGE.
 
 *mediainfo-0.7.63 (01 Jun 2013)
 
diff --git a/media-video/mediainfo/mediainfo-0.7.64.ebuild b/media-video/mediainfo/mediainfo-0.7.64.ebuild
new file mode 100644
index 000000000000..dc41f6c9e91a
--- /dev/null
+++ b/media-video/mediainfo/mediainfo-0.7.64.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/mediainfo-0.7.64.ebuild,v 1.1 2013/07/07 21:02:05 radhermit Exp $
+
+EAPI=5
+WX_GTK_VER="2.8"
+
+inherit eutils autotools wxwidgets multilib
+
+DESCRIPTION="MediaInfo supplies technical and tag information about media files"
+HOMEPAGE="http://mediaarea.net/mediainfo/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}_${PV}.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl mms wxwidgets"
+
+RDEPEND="sys-libs/zlib
+	media-libs/libzen
+	~media-libs/lib${P}[curl=,mms=]
+	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/MediaInfo
+
+pkg_setup() {
+	TARGETS="CLI"
+	use wxwidgets && TARGETS+=" GUI"
+}
+
+src_prepare() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target}
+		sed -i -e "s:-O2::" configure.ac
+		eautoreconf
+	done
+}
+
+src_configure() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target}
+		local args=""
+		[[ ${target} == "GUI" ]] && args="--with-wxwidgets --with-wx-gui"
+		econf ${args}
+	done
+}
+
+src_compile() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target}
+		default
+	done
+}
+src_install() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target}
+		default
+		dodoc "${S}"/History_${target}.txt
+		if [[ ${target} == "GUI" ]]; then
+			newicon "${S}"/Source/Resource/Image/MediaInfo.png ${PN}.png
+			make_desktop_entry ${PN}-gui MediaInfo ${PN} "AudioVideo;GTK"
+		fi
+	done
+}