Add 1.0.20070621 and remove nvidia-legacy-drivers from deps.

(Portage version: 2.1.3_rc9)

7 files changed, 118 insertions, 27 deletions

diff --git a/media-video/nvidia-settings/ChangeLog b/media-video/nvidia-settings/ChangeLog
index 5419f7fe3569..de64c4e783bd 100644
--- a/media-video/nvidia-settings/ChangeLog
+++ b/media-video/nvidia-settings/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-video/nvidia-settings
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/ChangeLog,v 1.33 2007/07/22 08:43:55 dberkholz Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/ChangeLog,v 1.34 2007/07/31 11:50:52 peper Exp $
+
+*nvidia-settings-1.0.20070621 (31 Jul 2007)
+
+  31 Jul 2007; Piotr Jaroszyński <peper@gentoo.org>
+  nvidia-settings-1.0.20051122-r3.ebuild,
+  nvidia-settings-1.0.20061102.ebuild, nvidia-settings-1.0.20070302.ebuild,
+  +nvidia-settings-1.0.20070621.ebuild:
+  Add 1.0.20070621 and remove nvidia-legacy-drivers from deps.
 
   22 Jul 2007; Donnie Berkholz <dberkholz@gentoo.org>;
   nvidia-settings-1.0.20051122-r3.ebuild:
diff --git a/media-video/nvidia-settings/files/digest-nvidia-settings-1.0.20070302 b/media-video/nvidia-settings/files/digest-nvidia-settings-1.0.20070302
index 9481c118f50c..f7533ffb8de9 100644
--- a/media-video/nvidia-settings/files/digest-nvidia-settings-1.0.20070302
+++ b/media-video/nvidia-settings/files/digest-nvidia-settings-1.0.20070302
@@ -1,3 +1,3 @@
-MD5 414a838f01093ceb0ae8535c35e21eac nvidia-settings-1.0.tar.gz 1100735
-RMD160 96f68ecde52aba2e58976406f4a907e4932b5f32 nvidia-settings-1.0.tar.gz 1100735
-SHA256 48e0a8b6a0b1cae6881e3c33cb0bdbddb34f7f7d009c91dc0a6826f94736c480 nvidia-settings-1.0.tar.gz 1100735
+MD5 414a838f01093ceb0ae8535c35e21eac nvidia-settings-1.0.20070302.tar.gz 1100735
+RMD160 96f68ecde52aba2e58976406f4a907e4932b5f32 nvidia-settings-1.0.20070302.tar.gz 1100735
+SHA256 48e0a8b6a0b1cae6881e3c33cb0bdbddb34f7f7d009c91dc0a6826f94736c480 nvidia-settings-1.0.20070302.tar.gz 1100735
diff --git a/media-video/nvidia-settings/files/digest-nvidia-settings-1.0.20070621 b/media-video/nvidia-settings/files/digest-nvidia-settings-1.0.20070621
new file mode 100644
index 000000000000..0c0b407b0f42
--- /dev/null
+++ b/media-video/nvidia-settings/files/digest-nvidia-settings-1.0.20070621
@@ -0,0 +1,3 @@
+MD5 0f4b41895f527481684a5bfe1de2d57b nvidia-settings-1.0.20070621.tar.gz 1254616
+RMD160 4cb1258ac6c3ae9f74eecb4fde79029a7c15f731 nvidia-settings-1.0.20070621.tar.gz 1254616
+SHA256 45ea3322866beab75927d30d5f8b299410b63cd6ebe3b797bd06bd7bf4ba702f nvidia-settings-1.0.20070621.tar.gz 1254616
diff --git a/media-video/nvidia-settings/nvidia-settings-1.0.20051122-r3.ebuild b/media-video/nvidia-settings/nvidia-settings-1.0.20051122-r3.ebuild
index 7807fdb20bc9..8268dcf6a8f6 100644
--- a/media-video/nvidia-settings/nvidia-settings-1.0.20051122-r3.ebuild
+++ b/media-video/nvidia-settings/nvidia-settings-1.0.20051122-r3.ebuild
@@ -1,13 +1,9 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/nvidia-settings-1.0.20051122-r3.ebuild,v 1.9 2007/07/22 08:43:55 dberkholz Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/nvidia-settings-1.0.20051122-r3.ebuild,v 1.10 2007/07/31 11:50:52 peper Exp $
 
 inherit eutils toolchain-funcs multilib
 
-# The following were added to work with the new nvidia-drivers and
-# nvidia-legacy-drivers ebuilds.
-NVIDIA_NEW_VERSION="1.0.8178"
-NVIDIA_LEGACY_VERSION="1.0.7182"
 S="${WORKDIR}/${PN}-1.0"
 DESCRIPTION="NVIDIA Linux X11 Settings Utility"
 HOMEPAGE="http://www.nvidia.com/"
@@ -33,9 +29,7 @@ DEPEND=">=x11-libs/gtk+-2
 		x11-proto/xf86driproto
 		x11-misc/imake
 		x11-misc/gccmakedep"
-RDEPEND="|| (
-			>=x11-drivers/nvidia-drivers-${NVIDIA_NEW_VERSION}
-			>=x11-drivers/nvidia-legacy-drivers-${NVIDIA_LEGACY_VERSION} )
+RDEPEND="x11-drivers/nvidia-drivers
 		>=x11-libs/gtk+-2
 		x11-base/xorg-server
 		x11-libs/libXt"
diff --git a/media-video/nvidia-settings/nvidia-settings-1.0.20061102.ebuild b/media-video/nvidia-settings/nvidia-settings-1.0.20061102.ebuild
index 83bfe3767b22..6579f1f7b94c 100644
--- a/media-video/nvidia-settings/nvidia-settings-1.0.20061102.ebuild
+++ b/media-video/nvidia-settings/nvidia-settings-1.0.20061102.ebuild
@@ -1,14 +1,9 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/nvidia-settings-1.0.20061102.ebuild,v 1.2 2007/03/07 21:57:40 peper Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/nvidia-settings-1.0.20061102.ebuild,v 1.3 2007/07/31 11:50:52 peper Exp $
 
 inherit eutils toolchain-funcs multilib
 
-# The following were added to work with the new nvidia-drivers and
-# nvidia-legacy-drivers ebuilds.
-NVIDIA_NEW_VERSION="1.0.9625"
-NVIDIA_LEGACY_VERSION="1.0.7182"
-S="${WORKDIR}/${PN}-1.0"
 DESCRIPTION="NVIDIA Linux X11 Settings Utility"
 HOMEPAGE="http://www.nvidia.com/"
 SRC_URI="mirror://gentoo/${P}.tar.gz
@@ -33,13 +28,13 @@ DEPEND=">=x11-libs/gtk+-2
 		x11-proto/xf86driproto
 		x11-misc/imake
 		x11-misc/gccmakedep"
-RDEPEND="|| (
-			>=x11-drivers/nvidia-drivers-${NVIDIA_NEW_VERSION}
-			>=x11-drivers/nvidia-legacy-drivers-${NVIDIA_LEGACY_VERSION} )
+RDEPEND="x11-drivers/nvidia-drivers
 		>=x11-libs/gtk+-2
 		x11-base/xorg-server
 		x11-libs/libXt"
 
+S="${WORKDIR}/${PN}-1.0"
+
 src_unpack() {
 	unpack ${A}
 	cd ${S}/src/libXNVCtrl
diff --git a/media-video/nvidia-settings/nvidia-settings-1.0.20070302.ebuild b/media-video/nvidia-settings/nvidia-settings-1.0.20070302.ebuild
index 220faf727c20..06ec41ca9fd0 100644
--- a/media-video/nvidia-settings/nvidia-settings-1.0.20070302.ebuild
+++ b/media-video/nvidia-settings/nvidia-settings-1.0.20070302.ebuild
@@ -1,16 +1,14 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/nvidia-settings-1.0.20070302.ebuild,v 1.2 2007/04/13 10:08:32 welp Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/nvidia-settings-1.0.20070302.ebuild,v 1.3 2007/07/31 11:50:52 peper Exp $
 
 inherit eutils toolchain-funcs multilib
 
 MY_P="${PN}-1.0"
-NVIDIA_NEW_VERSION="1.0.9625"
-NVIDIA_LEGACY_VERSION="1.0.7182"
 
 DESCRIPTION="NVIDIA Linux X11 Settings Utility"
 HOMEPAGE="http://www.nvidia.com/"
-SRC_URI="ftp://download.nvidia.com/XFree86/${PN}/${MY_P}.tar.gz"
+SRC_URI="http://dev.gentooexperimental.org/~peper/distfiles/${P}.tar.gz"
 
 LICENSE="GPL-2"
 SLOT="0"
@@ -34,8 +32,7 @@ DEPEND=">=x11-libs/gtk+-2
 RDEPEND=">=x11-libs/gtk+-2
 	x11-base/xorg-server
 	x11-libs/libXt
-	|| ( >=x11-drivers/nvidia-drivers-${NVIDIA_NEW_VERSION}
-		>=x11-drivers/nvidia-legacy-drivers-${NVIDIA_LEGACY_VERSION} )"
+	x11-drivers/nvidia-drivers"
 
 S="${WORKDIR}/${MY_P}"
 
diff --git a/media-video/nvidia-settings/nvidia-settings-1.0.20070621.ebuild b/media-video/nvidia-settings/nvidia-settings-1.0.20070621.ebuild
new file mode 100644
index 000000000000..63271246b814
--- /dev/null
+++ b/media-video/nvidia-settings/nvidia-settings-1.0.20070621.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/nvidia-settings-1.0.20070621.ebuild,v 1.1 2007/07/31 11:50:52 peper Exp $
+
+inherit eutils toolchain-funcs multilib
+
+MY_P="${PN}-1.0"
+
+DESCRIPTION="NVIDIA Linux X11 Settings Utility"
+HOMEPAGE="http://www.nvidia.com/"
+SRC_URI="http://dev.gentooexperimental.org/~peper/distfiles/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
+IUSE=""
+
+# xorg-server is used in the depends as nvidia-settings builds against some
+# headers in /usr/include/xorg/.
+# This also allows us to optimize out a lot of the other dependancies, as
+# between gtk and xorg-server, almost all libraries and headers are accounted
+# for.
+DEPEND=">=x11-libs/gtk+-2
+	dev-util/pkgconfig
+	x11-base/xorg-server
+	x11-libs/libXt
+	x11-libs/libXv
+	x11-proto/xf86driproto
+	x11-misc/imake
+	x11-misc/gccmakedep"
+
+RDEPEND=">=x11-libs/gtk+-2
+	x11-base/xorg-server
+	x11-libs/libXt
+	x11-drivers/nvidia-drivers"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${A}
+
+	cd "${S}/src/libXNVCtrl"
+	einfo "Tweaking libXNVCtrl for build..."
+
+	# This next voodoo is just to work around xmkmf's broken behaviour
+	# after the Xorg move to /usr (or I think, as I have not messed
+	# with it in ages).
+	#ln -snf /usr/include/X11 include
+
+	# Ensure that libNVCtrl.a is actually built
+	# Regardless of how NormalLibXrandr was built
+	# (NormalLibXrandr indicates if Xrandr was built as static or not)
+	# NormalLibXrandr was 'YES' in Xorg-6.8, but is 'NO' in 7.0.
+	sed -i.orig \
+		-e 's,DoNormalLib NormalLibXrandr,DoNormalLib YES,g' \
+		Imakefile
+
+	# for a rainy day, when we need a shared libXNVCtrl.so
+	#-e 'a#define DoSharedLib YES\n' \
+}
+
+src_compile() {
+	einfo "Building libXNVCtrl..."
+	cd "${S}/src/libXNVCtrl"
+	xmkmf -a || die "Running xmkmf failed!"
+	make clean || die "Cleaning old libXNVCtrl failed"
+	emake CDEBUGFLAGS="${CFLAGS}" CC="$(tc-getCC)" all || die "Building libXNVCtrl failed!"
+
+	cd "${S}"
+	einfo "Building nVidia-Settings..."
+	emake  CC="$(tc-getCC)" || die "Failed to build nvidia-settings"
+}
+
+src_install() {
+	# Install the executable
+	exeinto /usr/bin
+	doexe nvidia-settings
+
+	# Install libXNVCtrl and headers
+	insinto "/usr/$(get_libdir)"
+	doins src/libXNVCtrl/libXNVCtrl.a
+	insinto /usr/include/NVCtrl
+	doins src/libXNVCtrl/{NVCtrl,NVCtrlLib}.h
+
+	# Install icon and .desktop entry
+	doicon "${FILESDIR}/icon/${PN}.png"
+	domenu "${FILESDIR}/icon/${PN}.desktop"
+
+	# Install manpage
+	doman doc/nvidia-settings.1
+
+	# Now install documentation
+	dodoc doc/*.txt
+}